From fd8c338741e0a4b9350821c192bc87109ebdbfc8 Mon Sep 17 00:00:00 2001
From: "Liguros - Gitlab CI/CD [develop]" <gitlab@liguros.net>
Date: Thu, 11 May 2023 12:45:53 +0000
Subject: Adding metadata

---
 dev-python/fonttools/Manifest                |  1 +
 dev-python/fonttools/fonttools-4.39.4.ebuild | 67 ++++++++++++++++++++++++++++
 2 files changed, 68 insertions(+)
 create mode 100644 dev-python/fonttools/fonttools-4.39.4.ebuild

(limited to 'dev-python/fonttools')

diff --git a/dev-python/fonttools/Manifest b/dev-python/fonttools/Manifest
index 78e89f02607a..97dd326aa79b 100644
--- a/dev-python/fonttools/Manifest
+++ b/dev-python/fonttools/Manifest
@@ -1 +1,2 @@
 DIST fonttools-4.39.3.gh.tar.gz 3694939 BLAKE2B c2a758c226651866aecae198fe31dab20ff7ed2f67cfe2157eebc0c2254b537e711c5a190fc29c259326ded0d82e54801fed8caada0003a4e9e6e1b24bdc00a7 SHA512 84e7435308311cc8d8814dd54d6de4e863d9490d7214d981c372cf6d811dc5802c24b9dd9815c1b12bc1acdbb2e1b2075dac6308d0600f421cc1d9741d8f9410
+DIST fonttools-4.39.4.gh.tar.gz 3710610 BLAKE2B f4d75ae71c7b8ec752eee3820129719583072c8e1e68d54b3443c192e7c6732e7db7adfaec32145b87eccd23b1720a748e70682d58a1628d93f89890d3ddc274 SHA512 4be7c19022ccfbb182edb7d80ec50ff2aa91eae3dd4328c1023e65a293e079edd4c1ae0a8b2260e35fa940417e7b03dc96bd7a6d6ec4234bc4c4257187b24758
diff --git a/dev-python/fonttools/fonttools-4.39.4.ebuild b/dev-python/fonttools/fonttools-4.39.4.ebuild
new file mode 100644
index 000000000000..8ebccb763a7a
--- /dev/null
+++ b/dev-python/fonttools/fonttools-4.39.4.ebuild
@@ -0,0 +1,67 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_EXT=1
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10,11} )
+PYTHON_REQ_USE="xml(+)"
+
+inherit distutils-r1 virtualx
+
+DESCRIPTION="Library for manipulating TrueType, OpenType, AFM and Type1 fonts"
+HOMEPAGE="
+	https://github.com/fonttools/fonttools/
+	https://pypi.org/project/fonttools/
+"
+SRC_URI="
+	https://github.com/fonttools/fonttools/archive/${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~x64-macos"
+
+RDEPEND="
+	>=dev-python/fs-2.4.9[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	dev-python/cython[${PYTHON_USEDEP}]
+	test? (
+		app-arch/brotli[python,${PYTHON_USEDEP}]
+		app-arch/zopfli
+	)
+"
+
+distutils_enable_tests pytest
+
+python_prepare_all() {
+	# When dev-python/pytest-shutil is installed, we get weird import errors.
+	# This is due to incomplete nesting in the Tests/ tree:
+	#
+	#   Tests/feaLib/__init__.py
+	#   Tests/ufoLib/__init__.py
+	#   Tests/svgLib/path/__init__.py
+	#   Tests/otlLib/__init__.py
+	#   Tests/varLib/__init__.py
+	#
+	# This tree requires an __init__.py in Tests/svgLib/ too, bug #701148.
+	touch Tests/svgLib/__init__.py || die
+
+	distutils-r1_python_prepare_all
+}
+
+src_configure() {
+	export FONTTOOLS_WITH_CYTHON=1
+}
+
+src_test() {
+	# virtualx used when matplotlib is installed causing plot module tests to run
+	virtx distutils-r1_src_test
+}
+
+python_test() {
+	epytest Tests fontTools || die "Tests failed with ${EPYTHON}"
+}
-- 
cgit v1.3