From b590c8d7572b727d565cc0b8ff660d43569845de Mon Sep 17 00:00:00 2001
From: root <root@alpha.trunkmasters.com>
Date: Fri, 12 Jun 2026 19:09:37 -0500
Subject: Adding metadata

---
 dev-python/flit/Manifest           |  2 ++
 dev-python/flit/flit-3.12.0.ebuild | 60 ++++++++++++++++++++++++++++++++++++++
 dev-python/flit/metadata.xml       | 13 +++++++++
 3 files changed, 75 insertions(+)
 create mode 100644 dev-python/flit/Manifest
 create mode 100644 dev-python/flit/flit-3.12.0.ebuild
 create mode 100644 dev-python/flit/metadata.xml

(limited to 'dev-python/flit')

diff --git a/dev-python/flit/Manifest b/dev-python/flit/Manifest
new file mode 100644
index 000000000000..fc314d1199b7
--- /dev/null
+++ b/dev-python/flit/Manifest
@@ -0,0 +1,2 @@
+DIST flit-3.12.0.tar.gz 155038 BLAKE2B f38d846b78a4840fb94869393c5b757fbf54cf871d0318abdfa9172ddde22e0f2848b3ea4a51df57bce8539fb185308628f78d3e88c2ecd20d9ec51f9b825df9 SHA512 f8ed1f0e53452def182453db91a44c9ded5413fe74e2678bb7d56b3640d6ba6f43cccb55ad73e939cc5ca236fa2bf7b3e0f6d77fe4a4f12f90a9e437b561edb2
+DIST flit-3.12.0.tar.gz.provenance 8986 BLAKE2B d8ba7c142ac67ddc0b711a806916bad06eb72407cfca75d7543e0963e166752f802984f975d78d430b6e8c8810d340fc9e6989d6a0b4ae9589acf7c33a249a57 SHA512 6105c8ed244c2de39cff9d8e8d9d3b480b6a6a1937e0bd1e1cd5ec6854bbee4d26f95213b76b57baa139132cc88a32f66cdee52b88e1c3db83e59f82fca12b1d
diff --git a/dev-python/flit/flit-3.12.0.ebuild b/dev-python/flit/flit-3.12.0.ebuild
new file mode 100644
index 000000000000..fc3006097653
--- /dev/null
+++ b/dev-python/flit/flit-3.12.0.ebuild
@@ -0,0 +1,60 @@
+# Copyright 2019-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=flit
+PYPI_VERIFY_REPO=https://github.com/pypa/flit
+PYTHON_COMPAT=( python3_{13..14} )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Simplified packaging of Python modules"
+HOMEPAGE="
+	https://github.com/pypa/flit/
+	https://flit.readthedocs.io/
+	https://pypi.org/project/flit/
+"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~mips ~x86"
+
+RDEPEND="
+	dev-python/docutils[${PYTHON_USEDEP}]
+	>=dev-python/flit-core-${PV}[${PYTHON_USEDEP}]
+	dev-python/pip[${PYTHON_USEDEP}]
+	dev-python/requests[${PYTHON_USEDEP}]
+	dev-python/tomli-w[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	${RDEPEND}
+	sys-apps/grep
+	test? (
+		dev-python/responses[${PYTHON_USEDEP}]
+		dev-python/testpath[${PYTHON_USEDEP}]
+	)
+"
+
+EPYTEST_DESELECT=(
+	# requires Internet
+	tests/test_config.py::test_invalid_classifier
+	# failing due to Gentoo pip patches
+	tests/test_install.py::InstallTests::test_install_data_dir
+	tests/test_install.py::InstallTests::test_install_module_pep621
+	tests/test_install.py::InstallTests::test_symlink_data_dir
+	tests/test_install.py::InstallTests::test_symlink_module_pep621
+)
+
+EPYTEST_PLUGINS=()
+distutils_enable_tests pytest
+distutils_enable_sphinx doc \
+	dev-python/sphinxcontrib-github-alt \
+	dev-python/pygments-github-lexers \
+	dev-python/sphinx-rtd-theme
+
+src_prepare() {
+	# make sure system install is used
+	rm -r flit_core || die
+	distutils-r1_src_prepare
+}
diff --git a/dev-python/flit/metadata.xml b/dev-python/flit/metadata.xml
new file mode 100644
index 000000000000..21f304f4d584
--- /dev/null
+++ b/dev-python/flit/metadata.xml
@@ -0,0 +1,13 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://docs.baldeagleos.com/dtd/metadata.dtd">
+<pkgmetadata>
+  <maintainer type="person">
+    <email>chutzpah@gentoo.org</email>
+    <name>Patrick McLean</name>
+  </maintainer>
+  <maintainer type="project">
+    <email>python@gentoo.org</email>
+    <name>Python</name>
+  </maintainer>
+  <origin>baldeagleos-repo</origin>
+</pkgmetadata>
-- 
cgit v1.3