From b590c8d7572b727d565cc0b8ff660d43569845de Mon Sep 17 00:00:00 2001
From: root <root@alpha.trunkmasters.com>
Date: Fri, 12 Jun 2026 19:09:37 -0500
Subject: Adding metadata

---
 dev-python/flask/Manifest           |  2 ++
 dev-python/flask/flask-3.1.3.ebuild | 61 +++++++++++++++++++++++++++++++++++++
 dev-python/flask/metadata.xml       | 13 ++++++++
 3 files changed, 76 insertions(+)
 create mode 100644 dev-python/flask/Manifest
 create mode 100644 dev-python/flask/flask-3.1.3.ebuild
 create mode 100644 dev-python/flask/metadata.xml

(limited to 'dev-python/flask')

diff --git a/dev-python/flask/Manifest b/dev-python/flask/Manifest
new file mode 100644
index 000000000000..1e3903b8d674
--- /dev/null
+++ b/dev-python/flask/Manifest
@@ -0,0 +1,2 @@
+DIST flask-3.1.3.tar.gz 759004 BLAKE2B ff058d5d1f3565072704542245296ea709bf34061277b3681cb600705e201ca6d38153e02df3a3e3a6c9e7bf78add85fc9209c13509bd92ca687a89df4c5b945 SHA512 17c290fdccf3c7e45eeaf5d12a967889f6b0c6aac06a518624a18eb4de67904e825a2724d0c4d7701bb7e75a2f4629089a658e30909c6c7fe20992cc431b273e
+DIST flask-3.1.3.tar.gz.provenance 9221 BLAKE2B 8f06b8964259a210d39814f5905bcd22a0ed023a8394b47f63612ddc74261c81dfb4af74e29078c222bf14e699dc1647a0638d6887d802e424b6463b1a482c1e SHA512 f7a4b0843fc0cf133c68cb3778217b2561cc3af40af233a1ec96abed5869a74ebd190eb915489ff97461ea8401683996614146d1dd21e423b452215bfb7a18a8
diff --git a/dev-python/flask/flask-3.1.3.ebuild b/dev-python/flask/flask-3.1.3.ebuild
new file mode 100644
index 000000000000..54bd3ef78434
--- /dev/null
+++ b/dev-python/flask/flask-3.1.3.ebuild
@@ -0,0 +1,61 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=flit
+PYPI_VERIFY_REPO=https://github.com/pallets/flask
+PYTHON_COMPAT=( python3_{13..14} )
+
+inherit distutils-r1
+
+DESCRIPTION="A microframework based on Werkzeug, Jinja2 and good intentions"
+HOMEPAGE="
+	https://palletsprojects.com/p/flask/
+	https://github.com/pallets/flask/
+	https://pypi.org/project/Flask/
+"
+if [[ ${PV} == *9999* ]]; then
+	EGIT_REPO_URI="https://github.com/mitsuhiko/flask.git"
+	inherit git-r3
+else
+	inherit pypi
+	KEYWORDS="~alpha amd64 arm arm64 ~hppa ~loong ~mips ppc ppc64 ~riscv ~s390 ~sparc x86"
+fi
+
+LICENSE="BSD"
+SLOT="0"
+IUSE="examples"
+
+RDEPEND="
+	>=dev-python/blinker-1.9[${PYTHON_USEDEP}]
+	>=dev-python/click-8.1.3[${PYTHON_USEDEP}]
+	>=dev-python/itsdangerous-2.2.0[${PYTHON_USEDEP}]
+	>=dev-python/jinja2-3.1.2[${PYTHON_USEDEP}]
+	>=dev-python/werkzeug-3.1.0[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		>=dev-python/asgiref-3.2[${PYTHON_USEDEP}]
+		!!dev-python/shiboken2[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_sphinx docs \
+	dev-python/pallets-sphinx-themes \
+	dev-python/sphinx-issues \
+	dev-python/sphinx-tabs \
+	dev-python/sphinxcontrib-log-cabinet
+
+EPYTEST_PLUGINS=()
+distutils_enable_tests pytest
+
+EPYTEST_DESELECT=(
+	# removed in a31e6b73469cb2bf7eb8f70b5ff21f710fd2e23c
+	tests/test_reqctx.py::test_bad_environ_raises_bad_request
+)
+
+python_install_all() {
+	use examples && dodoc -r examples
+	distutils-r1_python_install_all
+}
diff --git a/dev-python/flask/metadata.xml b/dev-python/flask/metadata.xml
new file mode 100644
index 000000000000..a7bef1945951
--- /dev/null
+++ b/dev-python/flask/metadata.xml
@@ -0,0 +1,13 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://docs.baldeagleos.com/dtd/metadata.dtd">
+<pkgmetadata>
+  <maintainer type="project">
+    <email>python@gentoo.org</email>
+    <name>Python</name>
+  </maintainer>
+  <stabilize-allarches />
+  <upstream>
+    <remote-id type="cpe">cpe:/a:palletsprojects:flask</remote-id>
+  </upstream>
+  <origin>baldeagleos-repo</origin>
+</pkgmetadata>
-- 
cgit v1.3