From 9309e73601b94fbe27df1318837a556e61752f69 Mon Sep 17 00:00:00 2001
From: "Liguros - Gitlab CI/CD [develop]" <gitlab@liguros.net>
Date: Fri, 8 May 2026 19:15:21 +0000
Subject: Adding metadata

---
 dev-python/dropbox/Manifest                        |  2 +-
 dev-python/dropbox/dropbox-12.0.2.ebuild           | 49 ------------------
 dev-python/dropbox/dropbox-12.0.2_p20260506.ebuild | 59 ++++++++++++++++++++++
 3 files changed, 60 insertions(+), 50 deletions(-)
 delete mode 100644 dev-python/dropbox/dropbox-12.0.2.ebuild
 create mode 100644 dev-python/dropbox/dropbox-12.0.2_p20260506.ebuild

(limited to 'dev-python/dropbox')

diff --git a/dev-python/dropbox/Manifest b/dev-python/dropbox/Manifest
index cf1942f72469..ce32650dcad5 100644
--- a/dev-python/dropbox/Manifest
+++ b/dev-python/dropbox/Manifest
@@ -1 +1 @@
-DIST dropbox-sdk-python-12.0.2.gh.tar.gz 1155008 BLAKE2B cc0006909a204f0b9efab7605680027b144dfff5c91ddf31460884ada4948b285ff0777f19f9395a1fc447a906018c3a43b40bc7651bdbb715c597849e7ecba9 SHA512 73834c89e2dc8b129a549d082a7862ec81f731c4977c6650cc421c08b62903b78c9fa1e191a330022591e2cb0e29b825e89e2d04056e2f4e6362a168b57fec39
+DIST dropbox-12.0.2_p20260506.gh.tar.gz 1152945 BLAKE2B 728a269669ab835541c71068f05c401131fbe1d06f2f095a59e338d83cb5bd2bae674c8c1d050ae252a6af7db60e95b5be28e4b13f16296ecb35b6abd7efc450 SHA512 68ff810162ff945bcbcd9c6e7fb0cbf255b35b0964aa2391377a3cbe928b87a5408abc3cbccf4c9d2d0cde365393faf4e8186da1cff3b2d400732ac110eb404d
diff --git a/dev-python/dropbox/dropbox-12.0.2.ebuild b/dev-python/dropbox/dropbox-12.0.2.ebuild
deleted file mode 100644
index dd615e1b59b4..000000000000
--- a/dev-python/dropbox/dropbox-12.0.2.ebuild
+++ /dev/null
@@ -1,49 +0,0 @@
-# Copyright 2021-2024 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-DISTUTILS_USE_PEP517=setuptools
-PYTHON_COMPAT=( python3_{10..14} )
-inherit distutils-r1
-
-GH_PN=dropbox-sdk-python
-
-DESCRIPTION="The offical Dropbox SDK for Python"
-HOMEPAGE="https://www.dropbox.com/developers"
-# pypi does not have tests, stick with gh
-SRC_URI="https://github.com/dropbox/${GH_PN}/archive/refs/tags/v${PV}.tar.gz -> ${GH_PN}-${PV}.gh.tar.gz"
-S="${WORKDIR}"/${GH_PN}-${PV}
-
-LICENSE="MIT"
-SLOT="0"
-KEYWORDS="~amd64 ~x86"
-
-RDEPEND="
-	dev-python/requests[${PYTHON_USEDEP}]
-	dev-python/six[${PYTHON_USEDEP}]
-	dev-python/stone[${PYTHON_USEDEP}]
-	dev-python/urllib3[${PYTHON_USEDEP}]
-"
-# setuptools-82 removed 'pkg_resources'
-# https://github.com/dropbox/dropbox-sdk-python/issues/525
-BDEPEND="
-	<dev-python/setuptools-82.0.0[${PYTHON_USEDEP}]
-"
-
-# disable tests that need SCOPED_USER_DROPBOX_TOKEN
-# and tests that fail
-EPYTEST_DESELECT=(
-	test/integration/test_dropbox.py
-	test/unit/test_dropbox_unit.py::TestClient
-	test/unit/test_dropbox_unit.py::TestOAuth::test_NoRedirect_whole_flow
-)
-
-distutils_enable_tests pytest
-
-python_prepare_all() {
-	# this is wrong
-	sed -i -e "s/^import mock$/from unittest import mock/" test/unit/test_dropbox_unit.py || die
-
-	distutils-r1_python_prepare_all
-}
diff --git a/dev-python/dropbox/dropbox-12.0.2_p20260506.ebuild b/dev-python/dropbox/dropbox-12.0.2_p20260506.ebuild
new file mode 100644
index 000000000000..195af6f7eb18
--- /dev/null
+++ b/dev-python/dropbox/dropbox-12.0.2_p20260506.ebuild
@@ -0,0 +1,59 @@
+# Copyright 2021-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{10..14} )
+
+GIT_HASH="8223031ffad6b4b3ab4ee886658bc606e6f82bac"
+
+inherit distutils-r1
+
+MY_PN=dropbox-sdk-python
+MY_P=${MY_PN}-${PV}
+
+DESCRIPTION="The offical Dropbox SDK for Python"
+HOMEPAGE="https://www.dropbox.com/developers"
+
+# pypi does not have tests, stick with gh
+if [[ ${PV} == *_p* ]] ; then
+	SRC_URI="https://github.com/dropbox/${MY_PN}/archive/${GIT_HASH}.tar.gz -> ${P}.gh.tar.gz"
+	S="${WORKDIR}/${MY_PN}-${GIT_HASH}"
+else
+	SRC_URI="https://github.com/dropbox/${MY_PN}/archive/refs/tags/v${PV}.tar.gz -> ${P}.gh.tar.gz"
+	S="${WORKDIR}/${MY_P}"
+fi
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+RDEPEND="
+	>=dev-python/requests-2.16.2[${PYTHON_USEDEP}]
+	>=dev-python/six-1.12.0[${PYTHON_USEDEP}]
+	dev-python/stone[${PYTHON_USEDEP}]
+	dev-python/urllib3[${PYTHON_USEDEP}]
+"
+
+# disable tests that need SCOPED_USER_DROPBOX_TOKEN
+# and tests that fail
+EPYTEST_DESELECT=(
+	test/integration/test_dropbox.py
+	test/unit/test_dropbox_unit.py::TestClient
+	test/unit/test_dropbox_unit.py::TestOAuth::test_NoRedirect_whole_flow
+)
+
+distutils_enable_tests pytest
+
+src_prepare() {
+	if [[ ${PV} == *_p* ]] ; then
+		local MY_PV=$(ver_cut 1-3)
+
+		sed -i -e "s/__version__ = '0.0.0'/__version__ = '${MY_PV}'/" dropbox/dropbox_client.py || die
+	fi
+
+	sed -i -e "s/^import mock$/from unittest import mock/" test/unit/test_dropbox_unit.py || die
+
+	distutils-r1_src_prepare
+}
-- 
cgit v1.3