From 3ceeeb71476e4e7c29c37bbd1a2b3a97e34761e2 Mon Sep 17 00:00:00 2001
From: "Liguros - Gitlab CI/CD [develop]" <gitlab@liguros.net>
Date: Fri, 5 Sep 2025 08:13:23 +0000
Subject: Adding metadata

---
 dev-python/dnspython/dnspython-2.8.0_rc1.ebuild | 61 +++++++++++++++++++++++++
 1 file changed, 61 insertions(+)
 create mode 100644 dev-python/dnspython/dnspython-2.8.0_rc1.ebuild

(limited to 'dev-python/dnspython/dnspython-2.8.0_rc1.ebuild')

diff --git a/dev-python/dnspython/dnspython-2.8.0_rc1.ebuild b/dev-python/dnspython/dnspython-2.8.0_rc1.ebuild
new file mode 100644
index 000000000000..6bcf6bc5636d
--- /dev/null
+++ b/dev-python/dnspython/dnspython-2.8.0_rc1.ebuild
@@ -0,0 +1,61 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=hatchling
+PYTHON_COMPAT=( python3_{9,10,11,12,13} pypy3 )
+
+inherit distutils-r1
+
+MY_P=${P/_}
+DESCRIPTION="DNS toolkit for Python"
+HOMEPAGE="
+	https://www.dnspython.org/
+	https://github.com/rthalley/dnspython/
+	https://pypi.org/project/dnspython/
+"
+SRC_URI="
+	https://github.com/rthalley/dnspython/archive/v${PV/_}.tar.gz
+		-> ${MY_P}.gh.tar.gz
+"
+S=${WORKDIR}/${MY_P}
+
+LICENSE="ISC"
+SLOT="0"
+IUSE="dnssec examples https quic"
+
+RDEPEND="
+	dnssec? (
+		>=dev-python/cryptography-45[${PYTHON_USEDEP}]
+	)
+	>=dev-python/idna-2.1[${PYTHON_USEDEP}]
+	https? (
+		>=dev-python/httpx-0.26.0[${PYTHON_USEDEP}]
+		>=dev-python/h2-4.1.0[${PYTHON_USEDEP}]
+	)
+	quic? ( >=dev-python/aioquic-0.9.25[${PYTHON_USEDEP}] )
+"
+# note: skipping DoH test deps because they require Internet anyway
+BDEPEND="
+	test? (
+		>=dev-python/cryptography-45[${PYTHON_USEDEP}]
+		>=dev-python/quart-trio-0.11.0[${PYTHON_USEDEP}]
+	)
+"
+
+EPYTEST_PLUGINS=()
+distutils_enable_tests pytest
+
+python_test() {
+	local -x NO_INTERNET=1
+	epytest
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+	if use examples; then
+		dodoc -r examples
+		docompress -x /usr/share/doc/${PF}/examples
+	fi
+}
-- 
cgit v1.3.1