From 6fef7915014116f9db7834f594cfa6bd950c45aa Mon Sep 17 00:00:00 2001
From: "Liguros - Gitlab CI/CD [develop]" <gitlab@liguros.net>
Date: Wed, 19 Jan 2022 01:39:00 +0000
Subject: Adding metadata

---
 dev-python/dnspython/dnspython-2.2.0.ebuild | 46 +++++++++++++++++++++++++++++
 1 file changed, 46 insertions(+)
 create mode 100644 dev-python/dnspython/dnspython-2.2.0.ebuild

(limited to 'dev-python/dnspython/dnspython-2.2.0.ebuild')

diff --git a/dev-python/dnspython/dnspython-2.2.0.ebuild b/dev-python/dnspython/dnspython-2.2.0.ebuild
new file mode 100644
index 000000000000..310064e6989f
--- /dev/null
+++ b/dev-python/dnspython/dnspython-2.2.0.ebuild
@@ -0,0 +1,46 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{6,7,8,9,10} pypy3 )
+
+inherit distutils-r1
+
+DESCRIPTION="DNS toolkit for Python"
+HOMEPAGE="https://www.dnspython.org/
+	https://pypi.org/project/dnspython/"
+SRC_URI="https://github.com/rthalley/dnspython/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="ISC"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-solaris"
+IUSE="examples"
+
+RDEPEND="
+	dev-python/cryptography[${PYTHON_USEDEP}]
+	<dev-python/idna-4.0[${PYTHON_USEDEP}]"
+BDEPEND="
+	dev-python/setuptools_scm[${PYTHON_USEDEP}]"
+
+distutils_enable_tests pytest
+
+src_prepare() {
+	sed -i -e '/network_avail/s:True:False:' \
+		tests/*.py || die
+	distutils-r1_src_prepare
+
+	export SETUPTOOLS_SCM_PRETEND_VERSION=${PV}
+}
+
+python_test() {
+	epytest -s
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+	if use examples; then
+		dodoc -r examples
+		docompress -x /usr/share/doc/${PF}/examples
+	fi
+}
-- 
cgit v1.3.1