From b590c8d7572b727d565cc0b8ff660d43569845de Mon Sep 17 00:00:00 2001
From: root <root@alpha.trunkmasters.com>
Date: Fri, 12 Jun 2026 19:09:37 -0500
Subject: Adding metadata

---
 dev-python/django-cacheops/Manifest                |  1 +
 .../django-cacheops/django-cacheops-7.2.ebuild     | 68 ++++++++++++++++++++++
 dev-python/django-cacheops/metadata.xml            |  9 +++
 3 files changed, 78 insertions(+)
 create mode 100644 dev-python/django-cacheops/Manifest
 create mode 100644 dev-python/django-cacheops/django-cacheops-7.2.ebuild
 create mode 100644 dev-python/django-cacheops/metadata.xml

(limited to 'dev-python/django-cacheops')

diff --git a/dev-python/django-cacheops/Manifest b/dev-python/django-cacheops/Manifest
new file mode 100644
index 000000000000..9ccf3af2c879
--- /dev/null
+++ b/dev-python/django-cacheops/Manifest
@@ -0,0 +1 @@
+DIST django_cacheops-7.2.tar.gz 72751 BLAKE2B a2a36433d6f2d7d2e3364e9b8b51f2cfbb3bbd6217c9aebc6bb882ba261197be6a2d699227cd6de13eba1a7a5f9c4767f065c134bce7a89d76dbd735bbe214d9 SHA512 d8ba519e886cfb2de30ed9abcd2e648ce04a4efac80efd9e61bb4bd88845abc3b6d66f5c8ddea6819d127a9620f9a16acfe1c0b91e38ffb0aaeaff2bf410ae5d
diff --git a/dev-python/django-cacheops/django-cacheops-7.2.ebuild b/dev-python/django-cacheops/django-cacheops-7.2.ebuild
new file mode 100644
index 000000000000..8bec057d8675
--- /dev/null
+++ b/dev-python/django-cacheops/django-cacheops-7.2.ebuild
@@ -0,0 +1,68 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{13..14} )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="ORM cache with automatic granular event-driven invalidation for Django"
+HOMEPAGE="
+	https://github.com/Suor/django-cacheops/
+	https://pypi.org/project/django-cacheops/
+"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	>=dev-python/django-3.2[${PYTHON_USEDEP}]
+	>=dev-python/redis-2.9.1[${PYTHON_USEDEP}]
+	>=dev-python/funcy-1.8[${PYTHON_USEDEP}]
+	>=dev-python/six-1.4.0[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		${RDEPEND}
+		dev-db/redis
+		dev-python/dill[${PYTHON_USEDEP}]
+		dev-python/mock[${PYTHON_USEDEP}]
+	)
+"
+
+src_prepare() {
+	# Remove test dependent on unpackaged before_after
+	sed -e 's/test_lock/_&/' -i tests/test_extras.py || die
+	distutils-r1_src_prepare
+}
+
+python_test() {
+	local -x DJANGO_SETTINGS_MODULE=tests.settings
+	local -x PYTHONPATH=.
+	django-admin test -v 2 || die
+}
+
+src_test() {
+	local redis_pid="${T}"/redis.pid
+	local redis_port=6379
+
+	einfo "Spawning Redis"
+	einfo "NOTE: Port ${redis_port} must be free"
+	"${EPREFIX}"/usr/sbin/redis-server - <<-EOF || die
+		daemonize yes
+		pidfile ${redis_pid}
+		port ${redis_port}
+		bind 127.0.0.1
+	EOF
+
+	# Run the tests
+	distutils-r1_src_test
+
+	# Clean up afterwards
+	kill "$(<"${redis_pid}")" || die
+}
diff --git a/dev-python/django-cacheops/metadata.xml b/dev-python/django-cacheops/metadata.xml
new file mode 100644
index 000000000000..d34971a915e9
--- /dev/null
+++ b/dev-python/django-cacheops/metadata.xml
@@ -0,0 +1,9 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://docs.baldeagleos.com/dtd/metadata.dtd">
+<pkgmetadata>
+  <maintainer type="project">
+    <email>python@gentoo.org</email>
+  </maintainer>
+  <stabilize-allarches />
+  <origin>baldeagleos-repo</origin>
+</pkgmetadata>
-- 
cgit v1.3