From a0e0a56dbeec1a3cf0f82d55d0bd7540943daf84 Mon Sep 17 00:00:00 2001
From: root <root@alpha.trunkmasters.com>
Date: Tue, 28 Jul 2026 03:04:45 -0500
Subject: Adding metadata

---
 dev-python/deepdiff/Manifest              |  1 +
 dev-python/deepdiff/deepdiff-9.1.0.ebuild | 58 +++++++++++++++++++++++++++++++
 2 files changed, 59 insertions(+)
 create mode 100644 dev-python/deepdiff/deepdiff-9.1.0.ebuild

(limited to 'dev-python/deepdiff')

diff --git a/dev-python/deepdiff/Manifest b/dev-python/deepdiff/Manifest
index 84592625abfb..93c3ead8401f 100644
--- a/dev-python/deepdiff/Manifest
+++ b/dev-python/deepdiff/Manifest
@@ -1 +1,2 @@
 DIST deepdiff-8.6.2.tar.gz 634860 BLAKE2B bd73cd062827dae5dae2d0a9a4ad6376dbec90b5fcffc7f3f4e474da9c805fe8cb2e088e097359cebf9f6cb602e1235d6764a9f134317ca6c775501d7233f10b SHA512 d567ec5181ed0a4421b7d3bd0dcfc261e837f030d20e804a7687493f03476672c72f7897391e1ba7d6345c67689d642e0e1f8732ee589b6df86e9490cd881ab0
+DIST deepdiff-9.1.0.tar.gz 382149 BLAKE2B 0fb92ffe8e0ed0e2a4d648ec45cabeffa278b272b540217e165823c0e8af3b5a10a11fba4b7e703c28e276327820f8c2be1eacc040b0d87c5539ddd8cab5de69 SHA512 a01273f40b891be40e5a93ad4af1ce313a0c5a336bc66e6fb9d0769384687836863699761e1d98db9fb4cfd955957066a4eeb436ac2f4f4dcbae5c51fe14f79d
diff --git a/dev-python/deepdiff/deepdiff-9.1.0.ebuild b/dev-python/deepdiff/deepdiff-9.1.0.ebuild
new file mode 100644
index 000000000000..4b4cf27db75c
--- /dev/null
+++ b/dev-python/deepdiff/deepdiff-9.1.0.ebuild
@@ -0,0 +1,58 @@
+# Copyright 2023-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=flit-core
+PYTHON_COMPAT=( python3_{13..14} )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="A library for comparing dictionaries, iterables, strings and other objects"
+HOMEPAGE="
+	https://github.com/qlustered/deepdiff/
+	https://pypi.org/project/deepdiff/
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64"
+
+RDEPEND="
+	>=dev-python/cachebox-5.2[${PYTHON_USEDEP}]
+	>=dev-python/click-8.1.3[${PYTHON_USEDEP}]
+	>=dev-python/orderly-set-5.5.0[${PYTHON_USEDEP}]
+	>=dev-python/pyyaml-6.0[${PYTHON_USEDEP}]
+"
+
+DEPEND="
+	test? (
+		>=dev-python/jsonpickle-4.0.0[${PYTHON_USEDEP}]
+		>=dev-python/numpy-2.2.0[${PYTHON_USEDEP}]
+		>=dev-python/orjson-3.10.0[${PYTHON_USEDEP}]
+		dev-python/pandas[${PYTHON_USEDEP}]
+		dev-python/pydantic[${PYTHON_USEDEP}]
+		dev-python/python-dateutil[${PYTHON_USEDEP}]
+		dev-python/pytz[${PYTHON_USEDEP}]
+		dev-python/tomli-w[${PYTHON_USEDEP}]
+		dev-python/uuid6[${PYTHON_USEDEP}]
+	)
+"
+
+EPYTEST_PLUGINS=()
+distutils_enable_tests pytest
+
+EPYTEST_DESELECT=(
+	# benchmarks
+	tests/test_lfucache.py::TestDistanceCache::test_lru_cache
+	tests/test_lfucache.py::TestLFUcache::test_lfu
+	# requires polars
+	tests/test_hash.py::TestDeepHashPrep::test_polars
+)
+
+src_prepare() {
+	distutils-r1_src_prepare
+
+	# unpin dependencies
+	sed -i -e 's:,<[0-9.]*::' pyproject.toml || die
+}
-- 
cgit v1.3