From f716a9fe6455d39eef01e718aae68dae61c19704 Mon Sep 17 00:00:00 2001
From: root <root@alpha.trunkmasters.com>
Date: Thu, 4 Jun 2026 05:35:26 -0500
Subject: Adding metadata

---
 dev-python/dbus-python/Manifest                 |  1 -
 dev-python/dbus-python/dbus-python-1.4.0.ebuild | 94 -------------------------
 dev-python/dbus-python/metadata.xml             | 14 ----
 3 files changed, 109 deletions(-)
 delete mode 100644 dev-python/dbus-python/Manifest
 delete mode 100644 dev-python/dbus-python/dbus-python-1.4.0.ebuild
 delete mode 100644 dev-python/dbus-python/metadata.xml

(limited to 'dev-python/dbus-python')

diff --git a/dev-python/dbus-python/Manifest b/dev-python/dbus-python/Manifest
deleted file mode 100644
index 3ae74e8aa36b..000000000000
--- a/dev-python/dbus-python/Manifest
+++ /dev/null
@@ -1 +0,0 @@
-DIST dbus-python-1.4.0.tar.xz 168268 BLAKE2B 17ed4ed1d6f76acf4dc55dc9d281081d0bb412811f0b340edd8c2ef767802dd0386ffa39cdbc7a61870b916b20c89bee0d6a5b6b8e9355c84d2fdc846575e465 SHA512 defd5fba8348635ce52654b7e93e6cacf52966f6facfb7bb04fc77f2f82129e0b7673d4f3d483ef3321985172987d8c3265b27b9200c68c39c729567ffa21456
diff --git a/dev-python/dbus-python/dbus-python-1.4.0.ebuild b/dev-python/dbus-python/dbus-python-1.4.0.ebuild
deleted file mode 100644
index 71ead21b496b..000000000000
--- a/dev-python/dbus-python/dbus-python-1.4.0.ebuild
+++ /dev/null
@@ -1,94 +0,0 @@
-# Copyright 1999-2025 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-PYTHON_COMPAT=( python3_{13..14} )
-PYTHON_REQ_USE="threads(+)"
-
-inherit autotools python-r1
-
-DESCRIPTION="Python bindings for the D-Bus messagebus"
-HOMEPAGE="
-	https://www.freedesktop.org/wiki/Software/DBusBindings/
-	https://dbus.freedesktop.org/doc/dbus-python/
-"
-SRC_URI="https://dbus.freedesktop.org/releases/${PN}/${P}.tar.xz"
-
-LICENSE="MIT"
-SLOT="0"
-KEYWORDS="~alpha amd64 arm arm64 ~hppa ~loong ~mips ppc ppc64 ~riscv ~s390 ~sparc x86"
-IUSE="doc examples test"
-REQUIRED_USE="${PYTHON_REQUIRED_USE}"
-RESTRICT="!test? ( test )"
-
-DEPEND="
-	${PYTHON_DEPS}
-	>=sys-apps/dbus-1.8:=
-	>=dev-libs/glib-2.40
-"
-RDEPEND="
-	${DEPEND}
-"
-BDEPEND="
-	dev-build/autoconf-archive
-	virtual/pkgconfig
-	doc? (
-		$(python_gen_any_dep '
-			dev-python/sphinx[${PYTHON_USEDEP}]
-			dev-python/sphinx-rtd-theme[${PYTHON_USEDEP}]
-		')
-	)
-	test? (
-		dev-python/pygobject:3[${PYTHON_USEDEP}]
-		dev-python/tap-py[${PYTHON_USEDEP}]
-	)
-"
-
-python_check_deps() {
-	python_has_version "dev-python/sphinx[${PYTHON_USEDEP}]" \
-		"dev-python/sphinx-rtd-theme[${PYTHON_USEDEP}]"
-}
-
-src_prepare() {
-	default
-	# Update py-compile, bug 529502.
-	eautoreconf
-	python_copy_sources
-}
-
-src_configure() {
-	use doc && python_setup
-	local SPHINX_IMPL=${EPYTHON}
-
-	configuring() {
-		local myconf=(
-			--disable-documentation
-
-			# Work around broken AX_PYTHON_DEVEL macro.
-			# https://bugs.gentoo.org/815136
-			PYTHON_EXTRA_LIBS=' '
-		)
-		use doc && [[ ${EPYTHON} == ${SPHINX_IMPL} ]] &&
-			myconf+=( --enable-documentation )
-
-		econf "${myconf[@]}"
-	}
-	python_foreach_impl run_in_build_dir configuring
-}
-
-src_compile() {
-	python_foreach_impl run_in_build_dir default
-}
-
-src_test() {
-	unset DBUS_SESSION_BUS_ADDRESS
-	python_foreach_impl run_in_build_dir default
-}
-
-src_install() {
-	python_foreach_impl run_in_build_dir default
-	find "${D}" -name '*.la' -type f -delete || die
-
-	use examples && dodoc -r examples
-}
diff --git a/dev-python/dbus-python/metadata.xml b/dev-python/dbus-python/metadata.xml
deleted file mode 100644
index d65e0d4beebb..000000000000
--- a/dev-python/dbus-python/metadata.xml
+++ /dev/null
@@ -1,14 +0,0 @@
-<?xml version="1.0" encoding="UTF-8"?>
-<!DOCTYPE pkgmetadata SYSTEM "https://www.gentoo.org/dtd/metadata.dtd">
-<pkgmetadata>
-	<maintainer type="project">
-		<email>freedesktop-bugs@gentoo.org</email>
-	</maintainer>
-	<maintainer type="project">
-		<email>python@gentoo.org</email>
-		<name>Python</name>
-	</maintainer>
-	<upstream>
-		<remote-id type="pypi">dbus-python</remote-id>
-	</upstream>
-</pkgmetadata>
-- 
cgit v1.3.1