From c9dc4df0b1574b88fafd35faefcd4489901d40c2 Mon Sep 17 00:00:00 2001
From: "Liguros - Gitlab CI/CD [feature/flatten]" <gitlab@liguros.net>
Date: Mon, 26 Oct 2020 12:26:44 +0000
Subject: Updating liguros repo

---
 dev-python/cryptography/cryptography-3.2.ebuild | 53 +++++++++++++++++++++++++
 1 file changed, 53 insertions(+)
 create mode 100644 dev-python/cryptography/cryptography-3.2.ebuild

(limited to 'dev-python/cryptography/cryptography-3.2.ebuild')

diff --git a/dev-python/cryptography/cryptography-3.2.ebuild b/dev-python/cryptography/cryptography-3.2.ebuild
new file mode 100644
index 000000000000..19acf7dc2f7c
--- /dev/null
+++ b/dev-python/cryptography/cryptography-3.2.ebuild
@@ -0,0 +1,53 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{5,6,7,8,9} pypy3 )
+PYTHON_REQ_USE="threads(+)"
+
+inherit distutils-r1 multiprocessing
+
+VEC_P=cryptography_vectors-${PV}
+DESCRIPTION="Library providing cryptographic recipes and primitives"
+HOMEPAGE="https://github.com/pyca/cryptography/ https://pypi.org/project/cryptography/"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz
+	test? ( mirror://pypi/c/cryptography_vectors/${VEC_P}.tar.gz )"
+
+LICENSE="|| ( Apache-2.0 BSD )"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~x64-cygwin ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x64-solaris"
+IUSE="libressl idna"
+
+RDEPEND="
+	>=dev-python/six-1.4.1[${PYTHON_USEDEP}]
+	idna? ( >=dev-python/idna-2.1[${PYTHON_USEDEP}] )
+	$(python_gen_cond_dep '
+		>=dev-python/cffi-1.8:=[${PYTHON_USEDEP}]
+	' 'python*')
+	"
+BDEPEND="
+	test? (
+		>=dev-python/hypothesis-1.11.4[${PYTHON_USEDEP}]
+		dev-python/iso8601[${PYTHON_USEDEP}]
+		dev-python/pretend[${PYTHON_USEDEP}]
+		dev-python/pyasn1-modules[${PYTHON_USEDEP}]
+		dev-python/pytz[${PYTHON_USEDEP}]
+		dev-python/pytest-xdist[${PYTHON_USEDEP}]
+	)"
+
+distutils_enable_tests pytest
+
+DEPEND="
+	!libressl? ( >=dev-libs/openssl-1.0.2o-r6:0= )
+	libressl? ( >=dev-libs/libressl-2.9.1:0= )
+	"
+RDEPEND+=${DEPEND}
+
+DOCS=( AUTHORS.rst CONTRIBUTING.rst README.rst )
+
+python_test() {
+	local -x PYTHONPATH=${PYTHONPATH}:${WORKDIR}/${VEC_P}
+	pytest -vv -n "$(makeopts_jobs "${MAKEOPTS}" "$(get_nproc)")" ||
+		die "Tests fail with ${EPYTHON}"
+}
-- 
cgit v1.3