From b590c8d7572b727d565cc0b8ff660d43569845de Mon Sep 17 00:00:00 2001
From: root <root@alpha.trunkmasters.com>
Date: Fri, 12 Jun 2026 19:09:37 -0500
Subject: Adding metadata

---
 dev-python/cherrypy/Manifest                |  1 +
 dev-python/cherrypy/cherrypy-18.10.0.ebuild | 78 +++++++++++++++++++++++++++++
 dev-python/cherrypy/metadata.xml            | 13 +++++
 3 files changed, 92 insertions(+)
 create mode 100644 dev-python/cherrypy/Manifest
 create mode 100644 dev-python/cherrypy/cherrypy-18.10.0.ebuild
 create mode 100644 dev-python/cherrypy/metadata.xml

(limited to 'dev-python/cherrypy')

diff --git a/dev-python/cherrypy/Manifest b/dev-python/cherrypy/Manifest
new file mode 100644
index 000000000000..e31af79ed1a5
--- /dev/null
+++ b/dev-python/cherrypy/Manifest
@@ -0,0 +1 @@
+DIST cherrypy-18.10.0.tar.gz 633708 BLAKE2B b403ac983da855c7bf44b6909cc984a544d61cfa3191fae81f15b01d6b2d5d5e4bcd8c9f99c550e39540aac75d14523724602ddf121768c43bcbb93235e0941b SHA512 6c77d89e484fc1cf5a8e7523d1ebb04ba49930823905142ab016aabc80924e1173c97342f172585758c28faee1b329e26fe04dd1e36c559b7798495d45fdc36f
diff --git a/dev-python/cherrypy/cherrypy-18.10.0.ebuild b/dev-python/cherrypy/cherrypy-18.10.0.ebuild
new file mode 100644
index 000000000000..717713249ad3
--- /dev/null
+++ b/dev-python/cherrypy/cherrypy-18.10.0.ebuild
@@ -0,0 +1,78 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYPI_PN="CherryPy"
+PYTHON_COMPAT=( python3_{13..14} )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="CherryPy is a pythonic, object-oriented HTTP framework"
+HOMEPAGE="
+	https://cherrypy.dev/
+	https://github.com/cherrypy/cherrypy/
+	https://pypi.org/project/CherryPy/
+"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~alpha amd64 arm arm64 ~hppa ~loong ~m68k ~mips ppc ppc64 ~riscv ~s390 ~sparc x86"
+IUSE="ssl test"
+
+RDEPEND="
+	>=dev-python/cheroot-8.2.1[${PYTHON_USEDEP}]
+	>=dev-python/portend-2.1.1[${PYTHON_USEDEP}]
+	dev-python/more-itertools[${PYTHON_USEDEP}]
+	dev-python/zc-lockfile[${PYTHON_USEDEP}]
+	dev-python/jaraco-collections[${PYTHON_USEDEP}]
+	ssl? (
+		dev-python/pyopenssl[${PYTHON_USEDEP}]
+	)
+"
+BDEPEND="
+	dev-python/setuptools-scm[${PYTHON_USEDEP}]
+	test? (
+		dev-python/routes[${PYTHON_USEDEP}]
+		dev-python/simplejson[${PYTHON_USEDEP}]
+		dev-python/objgraph[${PYTHON_USEDEP}]
+		dev-python/path[${PYTHON_USEDEP}]
+		dev-python/requests-toolbelt[${PYTHON_USEDEP}]
+		!sparc? (
+			net-misc/memcached
+			dev-python/pylibmc[${PYTHON_USEDEP}]
+			dev-python/pytest-services[${PYTHON_USEDEP}]
+		)
+	)
+"
+
+distutils_enable_tests pytest
+
+python_prepare_all() {
+	sed -i -e '/cov/d' pytest.ini || die
+	# upstream has been using xfail to mark flaky tests, then added
+	# xfail_strict... not a good idea
+	sed -i -e '/xfail_strict/d' pytest.ini || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	local EPYTEST_DESELECT=()
+	local opts=()
+
+	# These tests are gracefully skipped when pylibmc is missing but not
+	# if pytest-services is missing -- even though that's the only test
+	# using these fixtures.
+	if ! has_version "dev-python/pytest-services[${PYTHON_USEDEP}]"; then
+		EPYTEST_DESELECT+=(
+			cherrypy/test/test_session.py::MemcachedSessionTest
+		)
+	else
+		opts+=( -p pytest-services )
+	fi
+
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	epytest "${opts[@]}"
+}
diff --git a/dev-python/cherrypy/metadata.xml b/dev-python/cherrypy/metadata.xml
new file mode 100644
index 000000000000..13811fb60b9c
--- /dev/null
+++ b/dev-python/cherrypy/metadata.xml
@@ -0,0 +1,13 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://docs.baldeagleos.com/dtd/metadata.dtd">
+<pkgmetadata>
+  <maintainer type="project">
+    <email>python@gentoo.org</email>
+    <name>Python</name>
+  </maintainer>
+  <stabilize-allarches />
+  <upstream>
+    <remote-id type="cpe">cpe:/a:cherrypy:cherrypy</remote-id>
+  </upstream>
+  <origin>baldeagleos-repo</origin>
+</pkgmetadata>
-- 
cgit v1.3