From a3ceca1b4c0d9bdb550dc23f06ffbb5a8e033bc7 Mon Sep 17 00:00:00 2001
From: root <root@alpha.trunkmasters.com>
Date: Thu, 4 Jun 2026 16:24:49 -0500
Subject: Adding metadata

---
 dev-python/cheroot/Manifest              |  2 -
 dev-python/cheroot/cheroot-11.1.2.ebuild | 92 --------------------------------
 dev-python/cheroot/metadata.xml          | 13 -----
 3 files changed, 107 deletions(-)
 delete mode 100644 dev-python/cheroot/Manifest
 delete mode 100644 dev-python/cheroot/cheroot-11.1.2.ebuild
 delete mode 100644 dev-python/cheroot/metadata.xml

(limited to 'dev-python/cheroot')

diff --git a/dev-python/cheroot/Manifest b/dev-python/cheroot/Manifest
deleted file mode 100644
index 476ba5bcf757..000000000000
--- a/dev-python/cheroot/Manifest
+++ /dev/null
@@ -1,2 +0,0 @@
-DIST cheroot-11.1.2.tar.gz 185716 BLAKE2B 421ef834498868ffcd97a50794b5809e806b618d37dfd200a17f5c09faf87d6e38b63f8e5f0ce4d28d308d54417768fb158198790627fa7e545075aa77aba179 SHA512 aaee92e15951756ffe3f5010d74e27894ac05ca55d866d1fc5c7ba3266ea5aedca3662ef53f55843b2b093d2e1ed92902e1c0d5bd52373f82a8c4f38f7329545
-DIST cheroot-11.1.2.tar.gz.provenance 9322 BLAKE2B a09532cf1b649aa72db93ad74dee22a96cc55817e4ce3befd9502a36b6de5182faa00aa6b7a276162305652f69e5027ab8dea74a6afbc6b4c5b0e02fd7c10e3e SHA512 60c40144845734eb9e776eae6530f4e565689176a348fe4ad0c6ef2fdf103604647e97f8fed3b3cc2fe631d73f979b579f6fb518a1a8e5b3aea1cc49b56492d6
diff --git a/dev-python/cheroot/cheroot-11.1.2.ebuild b/dev-python/cheroot/cheroot-11.1.2.ebuild
deleted file mode 100644
index 10abcc527533..000000000000
--- a/dev-python/cheroot/cheroot-11.1.2.ebuild
+++ /dev/null
@@ -1,92 +0,0 @@
-# Copyright 1999-2025 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-DISTUTILS_USE_PEP517=setuptools
-PYPI_VERIFY_REPO=https://github.com/cherrypy/cheroot
-PYTHON_COMPAT=( python3_{13..14} )
-
-inherit distutils-r1 pypi
-
-DESCRIPTION="High-performance, pure-Python HTTP server used by CherryPy"
-HOMEPAGE="
-	https://cherrypy.dev/
-	https://pypi.org/project/cheroot/
-	https://github.com/cherrypy/cheroot/
-"
-
-LICENSE="BSD"
-SLOT="0"
-KEYWORDS="~alpha amd64 arm arm64 ~hppa ~loong ~m68k ~mips ppc ppc64 ~riscv ~s390 ~sparc x86"
-IUSE="test-rust"
-
-RDEPEND="
-	>=dev-python/more-itertools-2.6[${PYTHON_USEDEP}]
-	dev-python/jaraco-functools[${PYTHON_USEDEP}]
-"
-BDEPEND="
-	>=dev-python/setuptools-scm-7.0.0[${PYTHON_USEDEP}]
-	test? (
-		dev-python/jaraco-context[${PYTHON_USEDEP}]
-		dev-python/jaraco-text[${PYTHON_USEDEP}]
-		dev-python/portend[${PYTHON_USEDEP}]
-		dev-python/requests-toolbelt[${PYTHON_USEDEP}]
-		dev-python/requests-unixsocket[${PYTHON_USEDEP}]
-		dev-python/urllib3[${PYTHON_USEDEP}]
-		test-rust? (
-			dev-python/pyopenssl[${PYTHON_USEDEP}]
-			dev-python/trustme[${PYTHON_USEDEP}]
-		)
-	)
-"
-
-EPYTEST_PLUGINS=( pytest-{mock,rerunfailures} )
-EPYTEST_XDIST=1
-distutils_enable_tests pytest
-
-python_prepare_all() {
-	sed -e '/cov/d' \
-		-e '/--numproc/d' \
-		-i pytest.ini || die
-
-	# broken
-	sed -i -e '/False.*localhost/d' cheroot/test/test_ssl.py || die
-	# pypytools is py2 stuff
-	sed -i -e '/pypytools/d' cheroot/test/test_server.py || die
-
-	distutils-r1_python_prepare_all
-}
-
-python_test() {
-	local EPYTEST_DESELECT=(
-		# requires pypytools, see above
-		cheroot/test/test_server.py::test_high_number_of_file_descriptors
-		# known test failures with OpenSSL 3.2.0
-		cheroot/test/test_ssl.py::test_https_over_http_error
-		# hardcoded errno codes (sigh)
-		# https://github.com/cherrypy/cheroot/issues/736
-		cheroot/test/test_errors.py::test_plat_specific_errors
-		cheroot/test/test_ssl.py::test_http_over_https_error
-	)
-
-	case ${EPYTHON} in
-		pypy3*)
-			EPYTEST_DESELECT+=(
-				# https://github.com/cherrypy/cheroot/issues/695
-				cheroot/test/test_conn.py::test_remains_alive_post_unhandled_exception
-			)
-			;;
-	esac
-
-	local EPYTEST_IGNORE=()
-	if ! has_version "dev-python/pyopenssl[${PYTHON_USEDEP}]" ||
-		! has_version "dev-python/trustme[${PYTHON_USEDEP}]"
-	then
-		EPYTEST_IGNORE+=(
-			cheroot/test/test_ssl.py
-		)
-	fi
-
-	epytest
-}
diff --git a/dev-python/cheroot/metadata.xml b/dev-python/cheroot/metadata.xml
deleted file mode 100644
index 303e66eaa698..000000000000
--- a/dev-python/cheroot/metadata.xml
+++ /dev/null
@@ -1,13 +0,0 @@
-<?xml version="1.0" encoding="UTF-8"?>
-<!DOCTYPE pkgmetadata SYSTEM "https://www.gentoo.org/dtd/metadata.dtd">
-<pkgmetadata>
-	<maintainer type="project">
-		<email>python@gentoo.org</email>
-		<name>Python</name>
-	</maintainer>
-	<stabilize-allarches/>
-	<upstream>
-		<remote-id type="pypi">cheroot</remote-id>
-		<remote-id type="github">cherrypy/cheroot</remote-id>
-	</upstream>
-</pkgmetadata>
-- 
cgit v1.3.1