From a39f855200a32a855dcddf447df0ff2beaa09def Mon Sep 17 00:00:00 2001
From: "Liguros - Gitlab CI/CD [develop]" <gitlab@liguros.net>
Date: Sat, 15 Apr 2023 01:00:42 +0000
Subject: Adding metadata

---
 dev-python/celery/Manifest                  |   1 +
 dev-python/celery/celery-5.3.0_beta2.ebuild | 117 ++++++++++++++++++++++++++++
 2 files changed, 118 insertions(+)
 create mode 100644 dev-python/celery/celery-5.3.0_beta2.ebuild

(limited to 'dev-python/celery')

diff --git a/dev-python/celery/Manifest b/dev-python/celery/Manifest
index e5bf84e1d780..8354dcef0de0 100644
--- a/dev-python/celery/Manifest
+++ b/dev-python/celery/Manifest
@@ -1 +1,2 @@
 DIST celery-5.3.0_beta1.gh.tar.gz 1509819 BLAKE2B 8864d9895823fde8ed1938a8b418906e624f14f6d306f1afb54bfc3c1897facfb22a85e368b2fb3ac96992d639e5f03589bfc78488de9ce060c88d9d1321e4ab SHA512 c617a03ca85120b7889eb94b36e41b3ba45b93acfe239c56c93b0860042a06fceaad1c396342e27f941ae58fd3d7468bf22d6b042b04e246b55abe5eedb63016
+DIST celery-5.3.0_beta2.gh.tar.gz 1539309 BLAKE2B 262b28dc72f689a888f6faae2ae5a8fde8d37cb3a07c76acb141ee922fd512f2bf621c5ec28b941b1b95e723e3cfe8ec00451a168c9f3b4e401f4aa2110aca2d SHA512 d8cf774050374ee4bead19135d2b7b5d6f3d48f724ccabd4fdcc487fffde58ee678988e95a18d463b0318a2e6617278aac1e22c528ed18f661f0139c2e728909
diff --git a/dev-python/celery/celery-5.3.0_beta2.ebuild b/dev-python/celery/celery-5.3.0_beta2.ebuild
new file mode 100644
index 000000000000..f4da3e35c424
--- /dev/null
+++ b/dev-python/celery/celery-5.3.0_beta2.ebuild
@@ -0,0 +1,117 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{7,8,9,10,11} )
+inherit bash-completion-r1 check-reqs distutils-r1 optfeature
+
+MY_PV="${PV/_beta/b}"
+DESCRIPTION="Asynchronous task queue/job queue based on distributed message passing"
+HOMEPAGE="
+	https://docs.celeryproject.org/en/stable/index.html
+	https://pypi.org/project/celery/
+	https://github.com/celery/celery
+"
+SRC_URI="https://github.com/celery/celery/archive/v${MY_PV}.tar.gz -> ${P}.gh.tar.gz"
+S="${WORKDIR}/${PN}-${MY_PV}"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="examples"
+
+RDEPEND="
+	>=dev-python/billiard-3.6.4.0[${PYTHON_USEDEP}]
+	<dev-python/billiard-5.0.0[${PYTHON_USEDEP}]
+	dev-python/click[${PYTHON_USEDEP}]
+	dev-python/click-didyoumean[${PYTHON_USEDEP}]
+	dev-python/click-plugins[${PYTHON_USEDEP}]
+	dev-python/click-repl[${PYTHON_USEDEP}]
+	>=dev-python/kombu-5.3.0_beta1[${PYTHON_USEDEP}]
+	<dev-python/kombu-6.0.0[${PYTHON_USEDEP}]
+	dev-python/pytz[${PYTHON_USEDEP}]
+	dev-python/vine[${PYTHON_USEDEP}]
+"
+
+BDEPEND="
+	test? (
+		$(python_gen_impl_dep 'ncurses(+)')
+		dev-python/azure-storage-blob[${PYTHON_USEDEP}]
+		>=dev-python/boto3-1.9.178[${PYTHON_USEDEP}]
+		dev-python/cryptography[${PYTHON_USEDEP}]
+		dev-python/elasticsearch-py[${PYTHON_USEDEP}]
+		>=dev-python/moto-1.3.7[${PYTHON_USEDEP}]
+		dev-python/msgpack[${PYTHON_USEDEP}]
+		dev-python/pylibmc[${PYTHON_USEDEP}]
+		dev-python/pymongo[${PYTHON_USEDEP}]
+		dev-python/pytest-celery[${PYTHON_USEDEP}]
+		dev-python/pytest-click[${PYTHON_USEDEP}]
+		dev-python/pytest-subtests[${PYTHON_USEDEP}]
+		>=dev-python/pytest-timeout-1.4.2[${PYTHON_USEDEP}]
+		>=dev-python/pyyaml-3.10[${PYTHON_USEDEP}]
+		dev-python/redis[${PYTHON_USEDEP}]
+		dev-python/sphinx-testing[${PYTHON_USEDEP}]
+		dev-python/tblib[${PYTHON_USEDEP}]
+		sci-astronomy/pyephem[${PYTHON_USEDEP}]
+	)
+	doc? (
+		dev-python/docutils[${PYTHON_USEDEP}]
+		>=dev-python/sphinx_celery-2.0.0[${PYTHON_USEDEP}]
+		>=dev-python/sphinx-click-2.5.0[${PYTHON_USEDEP}]
+		dev-python/jinja[${PYTHON_USEDEP}]
+		dev-python/sqlalchemy[${PYTHON_USEDEP}]
+	)
+"
+
+CHECKREQS_MEMORY="2G"
+
+EPYTEST_DESELECT=(
+	t/unit/backends/test_elasticsearch.py::test_ElasticsearchBackend::test_backend_concurrent_update
+	t/unit/backends/test_elasticsearch.py::test_ElasticsearchBackend::test_exception_safe_to_retry
+	t/unit/tasks/test_stamping.py::test_canvas_stamping::test_stamping_headers_in_options
+	t/unit/tasks/test_stamping.py::test_canvas_stamping::test_stamping_with_replace
+)
+
+distutils_enable_tests pytest
+distutils_enable_sphinx docs --no-autodoc
+
+pkg_setup() {
+	use test && check-reqs_pkg_setup
+}
+
+pkg_pretend() {
+	use test && check-reqs_pkg_pretend
+}
+
+python_install_all() {
+	# Main celeryd init.d and conf.d
+	newinitd "${FILESDIR}/celery.initd-r2" celery
+	newconfd "${FILESDIR}/celery.confd-r2" celery
+
+	if use examples; then
+		docinto examples
+		dodoc -r examples/.
+		docompress -x /usr/share/doc/${PF}/examples
+	fi
+
+	newbashcomp extra/bash-completion/celery.bash "${PN}"
+
+	distutils-r1_python_install_all
+}
+
+pkg_postinst() {
+	optfeature "msgpack support" dev-python/msgpack
+	#optfeature "rabbitmq support" dev-python/librabbitmq
+	#optfeature "slmq support" dev-python/softlayer_messaging
+	#optfeature "couchbase support" dev-python/couchbase
+	optfeature "redis support" dev-python/redis-py
+	optfeature "auth support" dev-python/pyopenssl
+	optfeature "yaml support" dev-python/pyyaml
+	optfeature "memcache support" dev-python/pylibmc
+	optfeature "mongodb support" dev-python/pymongo
+	optfeature "sqlalchemy support" dev-python/sqlalchemy
+	optfeature "sqs support" dev-python/boto
+	#optfeature "cassandra support" dev-python/cassandra-driver
+}
-- 
cgit v1.3.1