From df2f5c02a0eb345de8d703b44dd0c79a6c43ef26 Mon Sep 17 00:00:00 2001
From: "Liguros - Gitlab CI/CD [develop]" <gitlab@liguros.net>
Date: Sun, 27 Apr 2025 06:58:01 +0000
Subject: Adding metadata

---
 dev-python/cachecontrol/cachecontrol-0.14.2.ebuild | 46 ++++++++++++++++++++++
 1 file changed, 46 insertions(+)
 create mode 100644 dev-python/cachecontrol/cachecontrol-0.14.2.ebuild

(limited to 'dev-python/cachecontrol/cachecontrol-0.14.2.ebuild')

diff --git a/dev-python/cachecontrol/cachecontrol-0.14.2.ebuild b/dev-python/cachecontrol/cachecontrol-0.14.2.ebuild
new file mode 100644
index 000000000000..f28a507ca6cf
--- /dev/null
+++ b/dev-python/cachecontrol/cachecontrol-0.14.2.ebuild
@@ -0,0 +1,46 @@
+# Copyright 2022-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=flit
+PYTHON_COMPAT=( python3_{9,10,11,12,13} pypy3 )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="httplib2 caching for requests"
+HOMEPAGE="
+	https://pypi.org/project/CacheControl/
+	https://github.com/psf/cachecontrol/
+"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+
+RDEPEND="
+	<dev-python/msgpack-2[${PYTHON_USEDEP}]
+	>=dev-python/msgpack-0.5.2[${PYTHON_USEDEP}]
+	>=dev-python/requests-2.16.0[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/cherrypy[${PYTHON_USEDEP}]
+		>=dev-python/filelock-3.8.0[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+python_test() {
+	local EPYTEST_DESELECT=()
+
+	if [[ ${EPYTHON} == pypy3* ]]; then
+		EPYTEST_DESELECT+=(
+			tests/test_adapter.py::TestSessionActions::test_do_not_leak_response
+		)
+	fi
+
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	epytest
+}
-- 
cgit v1.3.1