From b590c8d7572b727d565cc0b8ff660d43569845de Mon Sep 17 00:00:00 2001
From: root <root@alpha.trunkmasters.com>
Date: Fri, 12 Jun 2026 19:09:37 -0500
Subject: Adding metadata

---
 dev-python/bottleneck/Manifest                |  1 +
 dev-python/bottleneck/bottleneck-1.6.0.ebuild | 58 +++++++++++++++++++++++++++
 dev-python/bottleneck/metadata.xml            | 13 ++++++
 3 files changed, 72 insertions(+)
 create mode 100644 dev-python/bottleneck/Manifest
 create mode 100644 dev-python/bottleneck/bottleneck-1.6.0.ebuild
 create mode 100644 dev-python/bottleneck/metadata.xml

(limited to 'dev-python/bottleneck')

diff --git a/dev-python/bottleneck/Manifest b/dev-python/bottleneck/Manifest
new file mode 100644
index 000000000000..167955343afe
--- /dev/null
+++ b/dev-python/bottleneck/Manifest
@@ -0,0 +1 @@
+DIST bottleneck-1.6.0.tar.gz 104311 BLAKE2B 1650d902e15bf3a2be36b83c9b460578bf0d261dd09cb74445a97fd2f20bd643e4985aa86acf2f2355f5a7341fde51d157815320b475852bdc8d46cab7943749 SHA512 e83d470b3380d579966855eef18c50069ca7db7a789ce0e8c39b707d0a8ad7cd2179121bad0c8bce41da5095ea1dea3dbfd59d31968ab21724d66baad694d978
diff --git a/dev-python/bottleneck/bottleneck-1.6.0.ebuild b/dev-python/bottleneck/bottleneck-1.6.0.ebuild
new file mode 100644
index 000000000000..dacc03e53255
--- /dev/null
+++ b/dev-python/bottleneck/bottleneck-1.6.0.ebuild
@@ -0,0 +1,58 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_EXT=1
+DISTUTILS_USE_PEP517=setuptools
+PYPI_PN=${PN^}
+PYTHON_COMPAT=( python3_{13..14} )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Fast NumPy array functions written in C"
+HOMEPAGE="
+	https://github.com/pydata/bottleneck/
+	https://pypi.org/project/Bottleneck/
+"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~alpha amd64 arm arm64 ~hppa ~loong ppc64 ~riscv ~s390 ~sparc x86 ~arm64-macos ~x64-macos"
+
+DEPEND="
+	>=dev-python/numpy-1.9.1:=[${PYTHON_USEDEP}]
+"
+RDEPEND="
+	${DEPEND}
+"
+BDEPEND="
+	dev-python/versioneer[${PYTHON_USEDEP}]
+"
+
+EPYTEST_PLUGINS=()
+distutils_enable_tests pytest
+
+src_prepare() {
+	# don't overwrites user's optimization level
+	sed -e '/extra_compile_args=\["-O2"\]/d' -i setup.py || die
+
+	rm versioneer.py || die
+
+	distutils-r1_src_prepare
+}
+
+python_test() {
+	local EPYTEST_DESELECT=()
+	case ${EPYTHON} in
+		pypy3*)
+			EPYTEST_DESELECT+=(
+				# GC assumptions?
+				tests/memory_test.py::test_memory_leak
+			)
+			;;
+	esac
+
+	rm -rf bottleneck || die
+	epytest --pyargs bottleneck
+}
diff --git a/dev-python/bottleneck/metadata.xml b/dev-python/bottleneck/metadata.xml
new file mode 100644
index 000000000000..2143e7861690
--- /dev/null
+++ b/dev-python/bottleneck/metadata.xml
@@ -0,0 +1,13 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://docs.baldeagleos.com/dtd/metadata.dtd">
+<pkgmetadata>
+  <maintainer type="project">
+    <email>sci-mathematics@gentoo.org</email>
+    <name>Gentoo Mathematics Project</name>
+  </maintainer>
+  <maintainer type="project">
+    <email>python@gentoo.org</email>
+    <name>Python</name>
+  </maintainer>
+  <origin>baldeagleos-repo</origin>
+</pkgmetadata>
-- 
cgit v1.3