From b590c8d7572b727d565cc0b8ff660d43569845de Mon Sep 17 00:00:00 2001
From: root <root@alpha.trunkmasters.com>
Date: Fri, 12 Jun 2026 19:09:37 -0500
Subject: Adding metadata

---
 dev-python/blockbuster/Manifest                  |  1 +
 dev-python/blockbuster/blockbuster-1.5.26.ebuild | 60 ++++++++++++++++++++++++
 dev-python/blockbuster/metadata.xml              |  9 ++++
 3 files changed, 70 insertions(+)
 create mode 100644 dev-python/blockbuster/Manifest
 create mode 100644 dev-python/blockbuster/blockbuster-1.5.26.ebuild
 create mode 100644 dev-python/blockbuster/metadata.xml

(limited to 'dev-python/blockbuster')

diff --git a/dev-python/blockbuster/Manifest b/dev-python/blockbuster/Manifest
new file mode 100644
index 000000000000..53635ead96c3
--- /dev/null
+++ b/dev-python/blockbuster/Manifest
@@ -0,0 +1 @@
+DIST blockbuster-1.5.26.tar.gz 36085 BLAKE2B 856a57dae55251771cd3340b1b6cad84fa168d7ca63630401fbbd8acf27b99d77759e3161b77f94abf7085035ef9303bf7b693561fad4cf8796009a2297bee5d SHA512 d12263e81c2acc97a537b3067632a6fc41af214125bd4c4c16f12079531fe4d6addc48091942fa5311dec6024113492ee585a185127c0cf69abfde4e3c1a8ce0
diff --git a/dev-python/blockbuster/blockbuster-1.5.26.ebuild b/dev-python/blockbuster/blockbuster-1.5.26.ebuild
new file mode 100644
index 000000000000..420d8f29776f
--- /dev/null
+++ b/dev-python/blockbuster/blockbuster-1.5.26.ebuild
@@ -0,0 +1,60 @@
+# Copyright 2025-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=hatchling
+PYTHON_COMPAT=( python3_{13..14} )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Utility to detect blocking calls in the async event loop"
+HOMEPAGE="
+	https://github.com/cbornet/blockbuster/
+	https://pypi.org/project/blockbuster/
+"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~alpha amd64 arm arm64 ~hppa ~loong ~mips ppc ppc64 ~riscv ~s390 ~sparc x86"
+
+RDEPEND="
+	$(python_gen_cond_dep '
+		>=dev-python/forbiddenfruit-0.1.4[${PYTHON_USEDEP}]
+	' 'python*')
+"
+BDEPEND="
+	test? (
+		dev-python/aiofiles[${PYTHON_USEDEP}]
+		dev-python/requests[${PYTHON_USEDEP}]
+	)
+"
+
+EPYTEST_PLUGINS=( pytest-asyncio )
+distutils_enable_tests pytest
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# Internet
+		tests/test_blockbuster.py::test_ssl_socket
+	)
+
+	case ${EPYTHON} in
+		pypy3.11)
+			EPYTEST_DESELECT+=(
+				# upstream doesn't care, however that doesn't stop
+				# people from depending on it...
+				# https://github.com/cbornet/blockbuster/issues/47
+				tests/test_blockbuster.py::test_file_random
+				tests/test_blockbuster.py::test_file_read_bytes
+				tests/test_blockbuster.py::test_file_text
+				tests/test_blockbuster.py::test_file_write_bytes
+				tests/test_blockbuster.py::test_lock
+				tests/test_blockbuster.py::test_os_scandir
+				tests/test_blockbuster.py::test_scanned_modules
+			)
+			;;
+	esac
+
+	epytest
+}
diff --git a/dev-python/blockbuster/metadata.xml b/dev-python/blockbuster/metadata.xml
new file mode 100644
index 000000000000..d34971a915e9
--- /dev/null
+++ b/dev-python/blockbuster/metadata.xml
@@ -0,0 +1,9 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://docs.baldeagleos.com/dtd/metadata.dtd">
+<pkgmetadata>
+  <maintainer type="project">
+    <email>python@gentoo.org</email>
+  </maintainer>
+  <stabilize-allarches />
+  <origin>baldeagleos-repo</origin>
+</pkgmetadata>
-- 
cgit v1.3