From 592a96bde875f8bfcb14ab34b0079f95e498d25d Mon Sep 17 00:00:00 2001
From: "Liguros - Gitlab CI/CD [develop]" <gitlab@liguros.net>
Date: Thu, 25 Mar 2021 01:47:21 +0000
Subject: Adding metadata

---
 .../aws-xray-sdk-python-2.7.0.ebuild               | 72 ++++++++++++++++++++++
 1 file changed, 72 insertions(+)
 create mode 100644 dev-python/aws-xray-sdk-python/aws-xray-sdk-python-2.7.0.ebuild

(limited to 'dev-python/aws-xray-sdk-python/aws-xray-sdk-python-2.7.0.ebuild')

diff --git a/dev-python/aws-xray-sdk-python/aws-xray-sdk-python-2.7.0.ebuild b/dev-python/aws-xray-sdk-python/aws-xray-sdk-python-2.7.0.ebuild
new file mode 100644
index 000000000000..fb35340f7400
--- /dev/null
+++ b/dev-python/aws-xray-sdk-python/aws-xray-sdk-python-2.7.0.ebuild
@@ -0,0 +1,72 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PYTHON_COMPAT=( python3_{6,7,8,9,10} )
+
+inherit distutils-r1
+
+DESCRIPTION="AWS X-Ray SDK for Python"
+HOMEPAGE="https://github.com/aws/aws-xray-sdk-python https://pypi.org/project/aws-xray-sdk/"
+SRC_URI="
+	https://github.com/aws/aws-xray-sdk-python/archive/${PV}.tar.gz
+		-> ${P}.gh.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~x86 ~amd64-linux ~x86-linux"
+IUSE=""
+
+RDEPEND="
+	>=dev-python/botocore-1.12.122[${PYTHON_USEDEP}]
+	dev-python/future[${PYTHON_USEDEP}]
+	dev-python/wrapt[${PYTHON_USEDEP}]"
+BDEPEND="
+	test? (
+		dev-python/bottle[${PYTHON_USEDEP}]
+		dev-python/django[${PYTHON_USEDEP}]
+		dev-python/flask-sqlalchemy[${PYTHON_USEDEP}]
+		dev-python/flask[${PYTHON_USEDEP}]
+		dev-python/mock[${PYTHON_USEDEP}]
+		dev-python/pytest-aiohttp[${PYTHON_USEDEP}]
+		<dev-python/sqlalchemy-1.4[${PYTHON_USEDEP}]
+		dev-python/webtest[${PYTHON_USEDEP}]
+	)"
+
+distutils_enable_tests pytest
+
+python_test() {
+	local -x DJANGO_SETTINGS_MODULE=tests.ext.django.app.settings
+	local -x AWS_SECRET_ACCESS_KEY=fake_key
+	local -x AWS_ACCESS_KEY_ID=fake_id
+
+	local args=(
+		# unpackaged deps
+		--ignore tests/ext/aiobotocore
+		--ignore tests/ext/pg8000
+		--ignore tests/ext/psycopg2
+		--ignore tests/ext/pymysql
+		--ignore tests/ext/pynamodb
+		--deselect tests/ext/django/test_db.py
+
+		# Internet access
+		--deselect
+		tests/test_patcher.py::test_external_file
+		--deselect
+		tests/test_patcher.py::test_external_module
+		--deselect
+		tests/test_patcher.py::test_external_submodules_full
+		--deselect
+		tests/test_patcher.py::test_external_submodules_ignores_file
+		--deselect
+		tests/test_patcher.py::test_external_submodules_ignores_module
+		--deselect
+		tests/ext/aiohttp/test_client.py
+		--ignore
+		tests/ext/httplib
+		--ignore
+		tests/ext/requests
+	)
+
+	epytest "${args[@]}"
+}
-- 
cgit v1.3.1