From b590c8d7572b727d565cc0b8ff660d43569845de Mon Sep 17 00:00:00 2001
From: root <root@alpha.trunkmasters.com>
Date: Fri, 12 Jun 2026 19:09:37 -0500
Subject: Adding metadata

---
 dev-python/apache-libcloud/Manifest                |  1 +
 .../apache-libcloud/apache-libcloud-3.9.1.ebuild   | 72 ++++++++++++++++++++++
 dev-python/apache-libcloud/metadata.xml            | 10 +++
 3 files changed, 83 insertions(+)
 create mode 100644 dev-python/apache-libcloud/Manifest
 create mode 100644 dev-python/apache-libcloud/apache-libcloud-3.9.1.ebuild
 create mode 100644 dev-python/apache-libcloud/metadata.xml

(limited to 'dev-python/apache-libcloud')

diff --git a/dev-python/apache-libcloud/Manifest b/dev-python/apache-libcloud/Manifest
new file mode 100644
index 000000000000..661443d41b01
--- /dev/null
+++ b/dev-python/apache-libcloud/Manifest
@@ -0,0 +1 @@
+DIST apache_libcloud-3.9.1.tar.gz 2582796 BLAKE2B 34e82709fc1082abc146afab5509c6580b97354c1f8d1d242826e487ffa73319aba1679945e27c71b19fc71d56a7fd188f67c6dadfd81eb4b64ccf11921e79a6 SHA512 e0d8cf84efaba4e01b7f76fa9e7246fba7fab780201ff2484d97666e350d3d56bc883ada68539f6ef263942b65958d89aa30f3fa6cce2dc3548cbe5e0c3a648e
diff --git a/dev-python/apache-libcloud/apache-libcloud-3.9.1.ebuild b/dev-python/apache-libcloud/apache-libcloud-3.9.1.ebuild
new file mode 100644
index 000000000000..d666b86eeeee
--- /dev/null
+++ b/dev-python/apache-libcloud/apache-libcloud-3.9.1.ebuild
@@ -0,0 +1,72 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{13..14} )
+PYTHON_REQ_USE="ssl(+)"
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Unified Interface to the Cloud - python support libs"
+HOMEPAGE="
+	https://libcloud.apache.org/
+	https://github.com/apache/libcloud/
+	https://pypi.org/project/apache-libcloud/
+"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="amd64 ~arm arm64 ~riscv x86"
+IUSE="examples"
+
+# Includes optional driver dependencies that are also test dependencies.
+RDEPEND="
+	>=dev-python/cryptography-44.0.2[${PYTHON_USEDEP}]
+	dev-python/fasteners[${PYTHON_USEDEP}]
+	>=dev-python/pyopenssl-25.0.0[${PYTHON_USEDEP}]
+	>=dev-python/requests-2.26.0[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/requests-mock[${PYTHON_USEDEP}]
+	)
+"
+
+EPYTEST_PLUGINS=()
+EPYTEST_XDIST=1
+distutils_enable_tests pytest
+
+src_prepare() {
+	distutils-r1_src_prepare
+
+	if use examples; then
+		mkdir examples || die
+		mv example_*.py examples || die
+	fi
+
+	# needed for tests
+	cp libcloud/test/secrets.py-dist libcloud/test/secrets.py || die
+}
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# TODO
+		libcloud/test/test_init.py::TestUtils::test_init_once_and_debug_mode
+		libcloud/test/common/test_openstack_identity.py::OpenStackIdentityConnectionTestCase::test_token_expiration_and_force_reauthenti
+	)
+	local EPYTEST_IGNORE=(
+		libcloud/test/benchmarks
+		# broken by modern paramiko
+		libcloud/test/compute/test_ssh_client.py
+	)
+
+	local -x NO_INTERNET=1
+	epytest
+}
+
+src_install() {
+	use examples && dodoc -r examples
+	distutils-r1_src_install
+}
diff --git a/dev-python/apache-libcloud/metadata.xml b/dev-python/apache-libcloud/metadata.xml
new file mode 100644
index 000000000000..5e95859f915a
--- /dev/null
+++ b/dev-python/apache-libcloud/metadata.xml
@@ -0,0 +1,10 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://docs.baldeagleos.com/dtd/metadata.dtd">
+<pkgmetadata>
+  <maintainer type="project">
+    <email>python@gentoo.org</email>
+    <name>Python</name>
+  </maintainer>
+  <stabilize-allarches />
+  <origin>baldeagleos-repo</origin>
+</pkgmetadata>
-- 
cgit v1.3.1