From 1f128f816bf9a9d272f22ee336c60cefc8291a7e Mon Sep 17 00:00:00 2001
From: "Liguros - Gitlab CI/CD [develop]" <gitlab@liguros.net>
Date: Tue, 22 Jun 2021 13:51:25 +0000
Subject: Adding metadata

---
 dev-python/agate-sql/agate-sql-0.5.6.ebuild | 58 +++++++++++++++++++++++++++++
 1 file changed, 58 insertions(+)
 create mode 100644 dev-python/agate-sql/agate-sql-0.5.6.ebuild

(limited to 'dev-python/agate-sql/agate-sql-0.5.6.ebuild')

diff --git a/dev-python/agate-sql/agate-sql-0.5.6.ebuild b/dev-python/agate-sql/agate-sql-0.5.6.ebuild
new file mode 100644
index 000000000000..095a168b4ad0
--- /dev/null
+++ b/dev-python/agate-sql/agate-sql-0.5.6.ebuild
@@ -0,0 +1,58 @@
+# Copyright 2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PYTHON_COMPAT=( python3_{6,7,8,9,10} )
+DISTUTILS_USE_SETUPTOOLS=bdepend
+
+inherit distutils-r1
+
+DESCRIPTION="Adds SQL read/write support to agate."
+HOMEPAGE="https://github.com/wireservice/agate-sql https://pypi.org/project/agate-sql/"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="test +xml"
+RESTRICT="!test? ( test )"
+
+# Other packages have BDEPEND="test? ( dev-python/agate-sql[xml] )"
+AGATE_VERSION_DEP=">=dev-python/agate-1.5.0"
+TEST_AGAINST_RDEPEND="xml? ( ${AGATE_VERSION_DEP}[xml,${PYTHON_USEDEP}] )"
+RDEPEND="
+	${AGATE_VERSION_DEP}[${PYTHON_USEDEP}]
+	>=dev-python/sqlalchemy-1.0.8[${PYTHON_USEDEP}]
+
+	${TEST_AGAINST_RDEPEND}
+"
+BDEPEND="test? ( ${AGATE_VERSION_DEP}[xml,${PYTHON_USEDEP}] )"
+
+distutils_enable_tests pytest
+
+python_prepare_all() {
+	local sed_args=(
+		-e "/crate/d"
+		-e "/nose/d"
+		-e "/geojson/d"
+		-e "/Sphinx/d"
+		-e "/sphinx_rtd_theme/d"
+	)
+
+	sed "${sed_args[@]}" -i setup.py agate_sql.egg-info/requires.txt || die
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	local pytest_args test_name xfails
+
+	xfails=(
+		tests/test_agatesql.py::TestSQL::test_to_sql_create_statement_with_dialects
+		tests/test_agatesql.py::TestSQL::test_to_sql_create_statement_with_schema
+	)
+
+	for test_name in "${xfails[@]}"; do
+		pytest_args+=(--deselect "${test_name}")
+	done
+
+	epytest "${pytest_args[@]}" || die
+}
-- 
cgit v1.3.1