From 0b00c63502240caf67b17715b317bbf574a0efb9 Mon Sep 17 00:00:00 2001
From: "Liguros - Gitlab CI/CD [develop]" <gitlab@liguros.net>
Date: Wed, 12 Jan 2022 13:40:12 +0000
Subject: Adding metadata

---
 dev-python/PySDL2/Manifest             |  1 +
 dev-python/PySDL2/PySDL2-0.9.10.ebuild | 55 ++++++++++++++++++++++++++++++++++
 2 files changed, 56 insertions(+)
 create mode 100644 dev-python/PySDL2/PySDL2-0.9.10.ebuild

(limited to 'dev-python/PySDL2')

diff --git a/dev-python/PySDL2/Manifest b/dev-python/PySDL2/Manifest
index d7c14151b7ff..fbbe1cb19202 100644
--- a/dev-python/PySDL2/Manifest
+++ b/dev-python/PySDL2/Manifest
@@ -1 +1,2 @@
+DIST PySDL2-0.9.10.tar.gz 5228778 BLAKE2B 1aac6ac3a33dd5cb56aad7e9fdcfe5ec62f7b406b9779aa04f92ec4f051cbe5f03596de06aa2d5688724c811c86959edefe40dab1e39980a8410c6b09c10c5ab SHA512 86517734d356ba7685914ce6e4583c8131bc2e84bf2318f985119407d39794878aeb8fdb84464e1e35c3b4cc1569777239dedb16f4669169f9f0302dacd8689e
 DIST PySDL2-0.9.9.tar.gz 743302 BLAKE2B 1e9e0eeea48b838227d3fe6ea93311d445b1d3a15588f4b83d075d18306b419ba3512826e44c5e4ecc2aec59ad44da73372ec740ebf6106271fd0b77175b88d7 SHA512 52b469735b1229392ea2f73b2dfcf1e75cedf7582a488461be9b06bc072f82a5c8c559d345a0c3668829c0f8bb2996005d538465ed7d2a45fb8480001fd0ccce
diff --git a/dev-python/PySDL2/PySDL2-0.9.10.ebuild b/dev-python/PySDL2/PySDL2-0.9.10.ebuild
new file mode 100644
index 000000000000..26145c9f75d0
--- /dev/null
+++ b/dev-python/PySDL2/PySDL2-0.9.10.ebuild
@@ -0,0 +1,55 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{6,7,8,9,10} )
+inherit distutils-r1
+
+DESCRIPTION="Python (ctypes) bindings for SDL2 libraries"
+HOMEPAGE="https://github.com/marcusva/py-sdl2 https://pypi.org/project/PySDL2/"
+SRC_URI="mirror://pypi/${PN::1}/${PN}/${P}.tar.gz"
+
+LICENSE="|| ( public-domain CC0-1.0 ZLIB )"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+# Optional deps:
+# - dev-python/numpy,
+# - dev-python/pillow,
+# - media-libs/sdl2-* (loaded dynamically via ctypes).
+#
+# If a reverse dependency needs the specific module, it should
+# explicitly depend on the optional module in question. You also
+# probably need to explicitly require some media-libs/libsdl2 flags.
+RDEPEND="media-libs/libsdl2"
+
+# Require all of SDL2 libraries and at least the most common subsystems
+# for better test coverage.
+DEPEND="
+	test? (
+		dev-python/numpy[${PYTHON_USEDEP}]
+		dev-python/pillow[${PYTHON_USEDEP}]
+		media-libs/libsdl2[joystick,sound,video]
+		media-libs/sdl2-gfx
+		media-libs/sdl2-image[gif,jpeg,png,tiff,webp]
+		|| (
+			media-libs/sdl2-mixer[flac]
+			media-libs/sdl2-mixer[midi]
+			media-libs/sdl2-mixer[mod]
+			media-libs/sdl2-mixer[mp3]
+			media-libs/sdl2-mixer[opus]
+		)
+		media-libs/sdl2-ttf
+	)"
+
+distutils_enable_tests pytest
+
+src_test() {
+	# from .travis.yml
+	local -x SDL_VIDEODRIVER=dummy
+	local -x SDL_AUDIODRIVER=dummy
+	local -x SDL_RENDER_DRIVER=software
+
+	distutils-r1_src_test
+}
-- 
cgit v1.3