From bf3d34248fe6ea7786aba6b2763dcf4fa111cb82 Mon Sep 17 00:00:00 2001
From: "Liguros - Gitlab CI/CD [develop]" <gitlab@liguros.net>
Date: Sat, 10 Apr 2021 01:49:00 +0000
Subject: Adding metadata

---
 dev-java/jspeex/jspeex-0.9.7-r1.ebuild | 57 ------------------------------
 dev-java/jspeex/jspeex-0.9.7-r2.ebuild | 63 ++++++++++++++++++++++++++++++++++
 2 files changed, 63 insertions(+), 57 deletions(-)
 delete mode 100644 dev-java/jspeex/jspeex-0.9.7-r1.ebuild
 create mode 100644 dev-java/jspeex/jspeex-0.9.7-r2.ebuild

(limited to 'dev-java/jspeex')

diff --git a/dev-java/jspeex/jspeex-0.9.7-r1.ebuild b/dev-java/jspeex/jspeex-0.9.7-r1.ebuild
deleted file mode 100644
index 294109eea94c..000000000000
--- a/dev-java/jspeex/jspeex-0.9.7-r1.ebuild
+++ /dev/null
@@ -1,57 +0,0 @@
-# Copyright 1999-2018 Gentoo Foundation
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI="5"
-
-JAVA_PKG_IUSE="doc source test"
-
-inherit base java-pkg-2 java-ant-2
-
-DESCRIPTION="Speex speech codec library for Java"
-HOMEPAGE="https://sourceforge.net/projects/jspeex/"
-SRC_URI="mirror://sourceforge/${PN}/${P}.zip"
-
-LICENSE="BSD"
-SLOT="0"
-KEYWORDS="~amd64 ~x86"
-
-CDEPEND="dev-java/ant-core:0"
-
-RDEPEND="${CDEPEND}
-	>=virtual/jre-1.4"
-
-DEPEND="${CDEPEND}
-	>=virtual/jdk-1.4
-	dev-java/junit:0
-	test? (
-		dev-java/ant-junit:0
-	)"
-
-JAVA_ANT_REWRITE_CLASSPATH="true"
-EANT_GENTOO_CLASSPATH="ant-core"
-EANT_BUILD_TARGET="package"
-
-S="${WORKDIR}/${PN}"
-
-java_prepare() {
-	epatch "${FILESDIR}"/${P}-remove-junit-report.patch
-	epatch "${FILESDIR}"/${P}-remove-proguard-taskdef.patch
-
-	find . -name "*.jar" -delete || die "Failed to remove bundled libraries."
-
-	cd lib || die
-	java-pkg_jar-from --build-only junit
-}
-
-src_test() {
-	ANT_TASKS="ant-junit ant-core" eant test
-}
-
-src_install() {
-	java-pkg_dojar dist/${PN}.jar
-
-	dodoc README TODO
-
-	use doc && java-pkg_dojavadoc doc/javadoc
-	use source && java-pkg_dosrc src/java/*
-}
diff --git a/dev-java/jspeex/jspeex-0.9.7-r2.ebuild b/dev-java/jspeex/jspeex-0.9.7-r2.ebuild
new file mode 100644
index 000000000000..18aaa3ba86c5
--- /dev/null
+++ b/dev-java/jspeex/jspeex-0.9.7-r2.ebuild
@@ -0,0 +1,63 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+JAVA_PKG_IUSE="doc source test"
+
+inherit java-pkg-2 java-ant-2
+
+DESCRIPTION="Speex speech codec library for Java"
+HOMEPAGE="https://sourceforge.net/projects/jspeex/"
+SRC_URI="mirror://sourceforge/${PN}/${P}.zip"
+S="${WORKDIR}/${PN}"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+CDEPEND="dev-java/ant-core:0"
+RDEPEND="
+	${CDEPEND}
+	>=virtual/jre-1.8:*
+"
+DEPEND="
+	${CDEPEND}
+	dev-java/junit:0
+	>=virtual/jdk-1.8:*
+	test? (
+		dev-java/ant-junit:0
+	)
+"
+BDEPEND="app-arch/unzip"
+
+JAVA_ANT_REWRITE_CLASSPATH="true"
+EANT_GENTOO_CLASSPATH="ant-core"
+EANT_BUILD_TARGET="package"
+
+PATCHES=(
+	"${FILESDIR}"/${P}-remove-junit-report.patch
+	"${FILESDIR}"/${P}-remove-proguard-taskdef.patch
+)
+
+src_prepare() {
+	default
+
+	java-pkg_clean
+
+	cd lib || die
+	java-pkg_jar-from --build-only junit
+}
+
+src_test() {
+	ANT_TASKS="ant-junit ant-core" eant test
+}
+
+src_install() {
+	java-pkg_dojar dist/${PN}.jar
+
+	dodoc README TODO
+
+	use doc && java-pkg_dojavadoc doc/javadoc
+	use source && java-pkg_dosrc src/java/*
+}
-- 
cgit v1.3.1