Updating liguros repo

11 files changed, 227 insertions, 34 deletions

diff --git a/sci-biology/HTSeq/HTSeq-0.9.1.ebuild b/sci-biology/HTSeq/HTSeq-0.12.4.ebuild
index 47079d8b270f..5e078675cf05 100644
--- a/sci-biology/HTSeq/HTSeq-0.9.1.ebuild
+++ b/sci-biology/HTSeq/HTSeq-0.12.4.ebuild
@@ -1,7 +1,7 @@
 # Copyright 1999-2020 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
-EAPI=6
+EAPI=7
 
 PYTHON_COMPAT=( python3_{5,6,7,8,9} )
 
@@ -12,9 +12,11 @@ HOMEPAGE="https://htseq.readthedocs.io/"
 
 if [[ ${PV} == *9999 ]]; then
 	inherit git-r3
-	EGIT_REPO_URI="https://github.com/simon-anders/htseq.git"
+	EGIT_REPO_URI="https://github.com/htseq/htseq.git"
 else
-	SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+	SRC_URI="https://github.com/htseq/htseq/archive/release_${PV}.tar.gz -> ${P}.tar.gz"
+
+	S="${WORKDIR}"/htseq-release_${PV}
 	KEYWORDS="~amd64"
 fi
 
@@ -25,7 +27,7 @@ RDEPEND="
 	dev-python/numpy[${PYTHON_USEDEP}]
 	dev-python/matplotlib[${PYTHON_USEDEP}]
 	sci-biology/pysam[${PYTHON_USEDEP}]"
-DEPEND="
-	${RDEPEND}
+DEPEND="${RDEPEND}"
+BDEPEND="
 	>=dev-lang/swig-3.0.8
 	dev-python/cython[${PYTHON_USEDEP}]"
diff --git a/sci-biology/HTSeq/HTSeq-9999.ebuild b/sci-biology/HTSeq/HTSeq-9999.ebuild
index 47079d8b270f..5e078675cf05 100644
--- a/sci-biology/HTSeq/HTSeq-9999.ebuild
+++ b/sci-biology/HTSeq/HTSeq-9999.ebuild
@@ -1,7 +1,7 @@
 # Copyright 1999-2020 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
-EAPI=6
+EAPI=7
 
 PYTHON_COMPAT=( python3_{5,6,7,8,9} )
 
@@ -12,9 +12,11 @@ HOMEPAGE="https://htseq.readthedocs.io/"
 
 if [[ ${PV} == *9999 ]]; then
 	inherit git-r3
-	EGIT_REPO_URI="https://github.com/simon-anders/htseq.git"
+	EGIT_REPO_URI="https://github.com/htseq/htseq.git"
 else
-	SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+	SRC_URI="https://github.com/htseq/htseq/archive/release_${PV}.tar.gz -> ${P}.tar.gz"
+
+	S="${WORKDIR}"/htseq-release_${PV}
 	KEYWORDS="~amd64"
 fi
 
@@ -25,7 +27,7 @@ RDEPEND="
 	dev-python/numpy[${PYTHON_USEDEP}]
 	dev-python/matplotlib[${PYTHON_USEDEP}]
 	sci-biology/pysam[${PYTHON_USEDEP}]"
-DEPEND="
-	${RDEPEND}
+DEPEND="${RDEPEND}"
+BDEPEND="
 	>=dev-lang/swig-3.0.8
 	dev-python/cython[${PYTHON_USEDEP}]"
diff --git a/sci-biology/HTSeq/Manifest b/sci-biology/HTSeq/Manifest
index d521aef0c0b0..92258c60174f 100644
--- a/sci-biology/HTSeq/Manifest
+++ b/sci-biology/HTSeq/Manifest
@@ -1 +1 @@
-DIST HTSeq-0.9.1.tar.gz 596941 BLAKE2B 6865c36056bff2008ae8bf18d0ac81dbf721fb97cdcc8bbd9150356fc80ae99e0cb872033fac274b40df3d1c95e9bcfd83c4f7d033184725596ffc96081e26d1 SHA512 ec3e1ec9cf66918f2afacf7997ab5da02015896ddd97260f5abec8343a9013cf6e857872be38b2cd3bb5bde655abe602a3c22c32448190f32e1a8f1153a19344
+DIST HTSeq-0.12.4.tar.gz 36187218 BLAKE2B 27be4e8783f9e32c10e23ae812069b489eb11dfa4058db43b5db4b8089792351901255103e4d4de1bcf866da3acd13e742adf8d35a9b70305aa156c70dde0837 SHA512 ec4a1a7e9177f103465840ffa9f936a5e887ffd17760b99d4cbdfd5a88e2ab44275fadfcbee153aadc6e828de7be205ed7a07f3a0548457b7c66826341c3ca64
diff --git a/sci-biology/bcftools/Manifest b/sci-biology/bcftools/Manifest
index eef8daed7a75..508a5c41fe37 100644
--- a/sci-biology/bcftools/Manifest
+++ b/sci-biology/bcftools/Manifest
@@ -1,2 +1,3 @@
+DIST bcftools-1.10.2.tar.bz2 3702679 BLAKE2B 51acce94d463868562199206504dc8afb50c671c11139c5a96f52cedf135bb7a46115c69411b9943b970a2395e3c866275c85e345a4a40a90194d1094698314e SHA512 f07e405efa16b9b1b18521342df3eaf840ed1b3028b736a6b4d139012ea85769ddfb3cd3a2c94958415d984d07805dfcd3d4bbec0db401b3f071b861a56d1300
 DIST bcftools-1.5.tar.bz2 2975685 BLAKE2B 937b7db770dcaddafbd00b67c3b88501a3190564b2ca629b83e52b48b414a604dd203cd067e357e2b7d02c700387576fca458d1cab2982dafa3b2c215b528722 SHA512 66b8bc61b9fbb381679a6781f77a18f66e8105567992da011413bc573d99b619558a1cf58e9e1373ae347a8b81638dd91977802a07a4578ddc9c61fb53403233
 DIST bcftools-1.9.tar.bz2 3134355 BLAKE2B dd551b509b1ee554f70be9da28a6eaf81dfcec43fc0d1aa972d64ef846f9db47f39177345e8c1ca754d11defb9c0823976ae94d6b3e7cd99313eed4f381182ed SHA512 fd662fb0d214eb75ac04fc4494e8dbaca84d10698ca14801427341def6a5df4af99e7bd4cd873da5422ae921deb49b940cedb926da356b1eabfac525a38f806c
diff --git a/sci-biology/bcftools/bcftools-1.10.2.ebuild b/sci-biology/bcftools/bcftools-1.10.2.ebuild
new file mode 100644
index 000000000000..4bbadb8eb2ef
--- /dev/null
+++ b/sci-biology/bcftools/bcftools-1.10.2.ebuild
@@ -0,0 +1,43 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{5,6,7,8,9} )
+
+inherit python-single-r1
+
+DESCRIPTION="Utilities for variant calling and manipulating VCF and BCF files"
+HOMEPAGE="https://www.htslib.org"
+SRC_URI="https://github.com/samtools/${PN}/releases/download/${PV}/${P}.tar.bz2"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+RDEPEND="
+	dev-lang/perl
+	$(python_gen_cond_dep '
+		dev-python/matplotlib[${PYTHON_MULTI_USEDEP}]
+	')
+	=sci-libs/htslib-${PV}*:=
+	sys-libs/zlib:=
+	${PYTHON_DEPS}"
+DEPEND="${RDEPEND}"
+
+src_prepare() {
+	default
+
+	python_fix_shebang misc/{guess-ploidy,plot-roh}.py
+
+	# remove bundled htslib
+	rm -r htslib-* || die
+}
+
+src_configure() {
+	econf \
+		--disable-bcftools-plugins \
+		--disable-libgsl \
+		--with-htslib=system
+}
diff --git a/sci-biology/pysam/Manifest b/sci-biology/pysam/Manifest
index 76bd71ffeb55..661592294a2b 100644
--- a/sci-biology/pysam/Manifest
+++ b/sci-biology/pysam/Manifest
@@ -1 +1,2 @@
 DIST pysam-0.12.0.1.tar.gz 2672020 BLAKE2B 4bc6330405724f7b1126da91ba3338687f4dd17f015895f42b971f22ffbb6c32eda65e2667035a4cc830c0370b34d95d3aa6ae0f026b2b3276af1fd6841eed28 SHA512 31460ca98ad2ac5489905ffce76bfbb5bf4a295159f3cc8e088c78dcfbfc34b30d6f7871fd1454de01da98f82b7438ac2aca678a771d7b97ae0029a418f29f1d
+DIST pysam-0.16.0.1.tar.gz 3294073 BLAKE2B 8df1c9b061b0d4b3962ff4b0e30f1589e02d7df41ce362bff861596d3599bf800bb16b2fa4de326fc07102dc7801b48c6b821e5d47e694a3536bec2c5b1cfece SHA512 5cebb9f3bc8dc6186a629e91423a3c8cb802af6529b943fcd880e056661ec6ee2a00de789cf144c9e40b9d1ef2459c0e06ce27a1b9eab8e2875d2087f275af28
diff --git a/sci-biology/pysam/files/pysam-0.16.0.1-fix-tests.patch b/sci-biology/pysam/files/pysam-0.16.0.1-fix-tests.patch
new file mode 100644
index 000000000000..9d269878e651
--- /dev/null
+++ b/sci-biology/pysam/files/pysam-0.16.0.1-fix-tests.patch
@@ -0,0 +1,37 @@
+--- a/tests/pysam_data/Makefile
++++ b/tests/pysam_data/Makefile
+@@ -3,7 +3,7 @@
+ BAI=$(BAM:%.bam=%.bam.bai)
+ CRAM=ex1.cram ex2.cram ex3.cram
+ CRAI=$(CRAM:%.cram=%.cram.crai)
+-NO_PG:=$(findstring --no-PG,$(shell samtools view))
++NO_PG:=--no-PG
+ 
+ # ex2.bam - bam file without index
+ 
+--- a/tests/tabix_test.py
++++ b/tests/tabix_test.py
+@@ -14,6 +14,7 @@
+ import subprocess
+ import glob
+ import re
++import pytest
+ from TestUtils import checkBinaryEqual, checkGZBinaryEqual, check_url, \
+     load_and_convert, TABIX_DATADIR, get_temp_filename
+ 
+@@ -1014,6 +1015,7 @@
+     globals()[n] = type(n, (TestVCFFromVariantFile,), dict(filename=vcf_file,))
+ 
+ 
++@pytest.mark.skip(reason="requires internet connectivity")
+ class TestRemoteFileHTTP(unittest.TestCase):
+ 
+     url = "http://genserv.anat.ox.ac.uk/downloads/pysam/test/example.gtf.gz"
+@@ -1053,6 +1055,7 @@
+         self.assertEqual(list(self.local_file.header), [])
+ 
+ 
++@pytest.mark.skip(reason="requires internet connectivity")
+ class TestRemoteFileHTTPWithHeader(TestRemoteFileHTTP):
+ 
+     url = "http://genserv.anat.ox.ac.uk/downloads/pysam/test/example_comments.gtf.gz"
diff --git a/sci-biology/pysam/pysam-0.16.0.1.ebuild b/sci-biology/pysam/pysam-0.16.0.1.ebuild
new file mode 100644
index 000000000000..c8036fbd4788
--- /dev/null
+++ b/sci-biology/pysam/pysam-0.16.0.1.ebuild
@@ -0,0 +1,60 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{5,6,7,8,9} )
+
+inherit distutils-r1
+
+DESCRIPTION="Python interface for the SAM/BAM sequence alignment and mapping format"
+HOMEPAGE="
+	https://github.com/pysam-developers/pysam
+	https://pypi.org/project/pysam/"
+SRC_URI="https://github.com/pysam-developers/pysam/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+RDEPEND="=sci-libs/htslib-1.10*:="
+DEPEND="${RDEPEND}
+	dev-python/cython[${PYTHON_USEDEP}]
+	dev-python/setuptools[${PYTHON_USEDEP}]"
+BDEPEND="
+	test? (
+		=sci-biology/bcftools-1.10*
+		=sci-biology/samtools-1.10*
+	)"
+
+distutils_enable_tests pytest
+
+DISTUTILS_IN_SOURCE_BUILD=1
+
+python_prepare_all() {
+	# unbundle htslib
+	export HTSLIB_MODE="external"
+	export HTSLIB_INCLUDE_DIR="${EPREFIX}"/usr/include
+	export HTSLIB_LIBRARY_DIR="${EPREFIX}"/usr/$(get_libdir)
+	rm -r htslib || die
+
+	# prevent setup.py from adding RPATHs (except $ORIGIN)
+	sed -e '/runtime_library_dirs=htslib_library_dirs/d' \
+		-i setup.py || die
+
+	eapply "${FILESDIR}"/${PN}-0.16.0.1-fix-tests.patch
+
+	if use test; then
+		einfo "Building test data"
+		emake -C tests/pysam_data
+		emake -C tests/cbcf_data
+	fi
+
+	distutils-r1_python_prepare_all
+}
+
+python_compile() {
+	# breaks with parallel build
+	local MAKEOPTS=-j1
+	distutils-r1_python_compile
+}
diff --git a/sci-biology/samtools/Manifest b/sci-biology/samtools/Manifest
index 7ce21379a95d..b06f63a40e78 100644
--- a/sci-biology/samtools/Manifest
+++ b/sci-biology/samtools/Manifest
@@ -1,3 +1,4 @@
 DIST samtools-0.1.20.tar.gz 566387 BLAKE2B a62d74c408877754af50f5e5fea0e2289ec1e0c9f25013ed0d039bfe8ef61108600d917f8c9d356e98aca632795b4eb0f01ea1b54526a652577fb74a38a433c2 SHA512 15bd8cf401d14c1ab4faa591b6054f5ea9731c4e966f37f71d33d9081a270cfeb91e8a3d80c631e0725b49da81387f824c206e8c21553ad554d0cfc5c238a6e5
+DIST samtools-1.10.tar.bz2 4721173 BLAKE2B 103c71ec5740eac151a4fc40d67286ee00123c7befd5f654cf5c89812bda44f82b38ab662a4a3216ac84434cabab49500b903612137f97f89a7ea38063e8fc08 SHA512 828ec2638592b440e06b81eafc57634416ab54dac6caaecb06f22a90e9bf99da1fd8bb54509cb98591899c4e097ac9038ee5d57ea7bfe1a18967cde4018d840a
 DIST samtools-1.5.tar.bz2 4190142 BLAKE2B 1d3478f9adf76925a3721e145795ce4a4caf580244f5ba5bc1ddd14d1b13c723c6fddc24cdadf0a23ca5dcd7007a9985f54e7532cb15d5d9433b1164f5a22023 SHA512 ff3e39ba867ecbd88f3363b038508c1557e349ea4223483f8f4ecb17ff8864fb53cd193bc2059a147e30f07395bbf53c8518d0f70219e454375c8bffe56e3059
 DIST samtools-1.9.tar.bz2 4440405 BLAKE2B 409265fed9ff3fcd09096c968224499750da69324eeded754e367430c0f53f9246ccc9a31e166f13ea7bc767fefab499bcfda4d008d5ac82971984c67b533aff SHA512 6c8207754615ae8dad84b278f93e7d57eb40b818efb80f6aff6aba22fde5772247724e86596e765791e3175ffbb683393dd3ddfe7681c73eef4eb4f2342bf68f
diff --git a/sci-biology/samtools/samtools-0.1.20-r3.ebuild b/sci-biology/samtools/samtools-0.1.20-r4.ebuild
index 35adedfd2f67..ef129bae67e0 100644
--- a/sci-biology/samtools/samtools-0.1.20-r3.ebuild
+++ b/sci-biology/samtools/samtools-0.1.20-r4.ebuild
@@ -1,11 +1,9 @@
-# Copyright 1999-2016 Gentoo Foundation
+# Copyright 1999-2020 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
-EAPI=6
+EAPI=7
 
-PYTHON_COMPAT=( python2_7 )
-
-inherit python-single-r1 toolchain-funcs
+inherit toolchain-funcs
 
 DESCRIPTION="Utilities for analysing and manipulating the SAM/BAM alignment formats"
 HOMEPAGE="https://sourceforge.net/projects/samtools/"
@@ -14,23 +12,17 @@ SRC_URI="https://github.com/samtools/samtools/archive/${PV}.tar.gz -> ${P}.tar.g
 LICENSE="MIT"
 SLOT="0.1-legacy"
 KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux ~x64-macos"
-IUSE="examples"
-REQUIRED_USE="${PYTHON_REQUIRED_USE}"
 
-RDEPEND="${PYTHON_DEPS}
+RDEPEND="
 	sys-libs/ncurses:0=
 	dev-lang/perl"
-DEPEND="${RDEPEND}
-	virtual/pkgconfig"
+DEPEND="${RDEPEND}"
+BDEPEND="virtual/pkgconfig"
 
-PATCHES=(
-	"${FILESDIR}/${P}-buildsystem.patch"
-)
+PATCHES=( "${FILESDIR}"/${P}-buildsystem.patch )
 
 src_prepare() {
 	default
-	# required, otherwise python_fix_shebang errors out
-	sed -i 's~/software/bin/python~/usr/bin/env python~' misc/varfilter.py || die
 	tc-export CC AR
 }
 
@@ -48,9 +40,9 @@ src_install() {
 	mkdir "${ED%/}"/usr/bin || die
 	mv "${ED%/}"/usr/{${PN}-${SLOT},bin/} || die
 
-	# ... do the same with the python script, but also fix the shebang
-	mv "${ED%/}"/usr/bin/${PN}-${SLOT}/varfilter{,-${SLOT}}.py || die
-	python_fix_shebang "${ED%/}"/usr/bin/${PN}-${SLOT}/varfilter-${SLOT}.py
+	# remove py2 script, has been removed upstream anyways
+	# https://github.com/samtools/samtools/issues/1125
+	rm "${ED%/}"/usr/bin/${PN}-${SLOT}/varfilter.py || die
 
 	# fix perl shebangs
 	pushd "${ED%/}"/usr/bin/${PN}-${SLOT} >/dev/null || die
@@ -70,14 +62,12 @@ src_install() {
 	doman ${PN}-${SLOT}.1
 	einstalldocs
 
-	if use examples; then
-		dodoc -r examples
-		docompress -x /usr/share/doc/${PF}/examples
-	fi
+	dodoc -r examples
+	docompress -x /usr/share/doc/${PF}/examples
 }
 
 pkg_postinst() {
 	elog "This version of samtools should *not* be your first choice for working"
 	elog "with NGS data. It is installed solely for programs requiring it."
-	elog "It is recommended that you use >=sci-biology/samtools-1.2."
+	elog "It is recommended that you use >=sci-biology/samtools-1.10."
 }
diff --git a/sci-biology/samtools/samtools-1.10.ebuild b/sci-biology/samtools/samtools-1.10.ebuild
new file mode 100644
index 000000000000..69aa470f8113
--- /dev/null
+++ b/sci-biology/samtools/samtools-1.10.ebuild
@@ -0,0 +1,56 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit autotools toolchain-funcs
+
+DESCRIPTION="Utilities for analysing and manipulating the SAM/BAM alignment formats"
+HOMEPAGE="https://www.htslib.org/"
+SRC_URI="mirror://sourceforge/${PN}/${P}.tar.bz2"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux ~x64-macos"
+
+RDEPEND="
+	dev-lang/perl
+	=sci-libs/htslib-${PV}*
+	sys-libs/ncurses:0=[unicode]
+	sys-libs/zlib:="
+DEPEND="${RDEPEND}"
+BDEPEND="virtual/pkgconfig"
+
+src_prepare() {
+	default
+
+	# remove bundled htslib
+	rm -r htslib-* || die
+
+	eautoreconf
+}
+
+src_configure() {
+	econf \
+		--with-ncurses \
+		--with-htslib=system \
+		CURSES_LIB="$($(tc-getPKG_CONFIG) --libs ncursesw)"
+}
+
+src_compile() {
+	emake AR="$(tc-getAR)"
+}
+
+src_test() {
+	# the tview test diffs expect 80-columns output
+	unset COLUMNS
+
+	default
+}
+
+src_install() {
+	default
+
+	dodoc -r examples
+	docompress -x /usr/share/doc/${PF}/examples
+}