Updating liguros repo

4 files changed, 125 insertions, 0 deletions

diff --git a/dev-python/dbus-python/Manifest b/dev-python/dbus-python/Manifest
new file mode 100644
index 000000000000..40ba4cdce245
--- /dev/null
+++ b/dev-python/dbus-python/Manifest
@@ -0,0 +1 @@
+DIST dbus-python-1.2.16.tar.gz 576701 BLAKE2B 58d9f9ea092cd3a6b872c084a6159baf03f1aab615282e161a0e3da1d01ff5f4940862e693d21907b0c146d285b9067386759a1306ae2e6907f5e2ff4ef9944d SHA512 e76c00c5fd3fe6884e4c24f258987fd3b80d21bd4e0f96aa8fda152078a860b62321324f6efcbfe7226d5ab2521a14b5bda7cf2468d2cae5f376c124a71aa05c
diff --git a/dev-python/dbus-python/dbus-python-1.2.16.ebuild b/dev-python/dbus-python/dbus-python-1.2.16.ebuild
new file mode 100644
index 000000000000..e07d2500f718
--- /dev/null
+++ b/dev-python/dbus-python/dbus-python-1.2.16.ebuild
@@ -0,0 +1,79 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python2_7 python3_{6,7,8,9} )
+PYTHON_REQ_USE="threads(+)"
+
+inherit autotools python-r1
+
+DESCRIPTION="Python bindings for the D-Bus messagebus"
+HOMEPAGE="https://www.freedesktop.org/wiki/Software/DBusBindings https://dbus.freedesktop.org/doc/dbus-python/"
+SRC_URI="https://dbus.freedesktop.org/releases/${PN}/${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha amd64 arm arm64 hppa ~ia64 ~mips ppc ppc64 ~s390 sparc x86"
+
+IUSE="doc examples test"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+RESTRICT="!test? ( test )"
+
+RDEPEND="${PYTHON_DEPS}
+	>=sys-apps/dbus-1.8:=
+	>=dev-libs/glib-2.40
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	virtual/pkgconfig
+	doc? ( $(python_gen_any_dep 'dev-python/sphinx[${PYTHON_USEDEP}]') )
+	test? ( dev-python/pygobject:3[${PYTHON_USEDEP}]
+		dev-python/tappy[${PYTHON_USEDEP}] )
+"
+
+PATCHES=( "${FILESDIR}/${P}-py39.patch" )
+
+python_check_deps() {
+	has_version "dev-python/sphinx[${PYTHON_USEDEP}]"
+}
+
+src_prepare() {
+	default
+	# Update py-compile, bug 529502.
+	eautoreconf
+	python_copy_sources
+}
+
+src_configure() {
+	use doc && python_setup
+	local SPHINX_IMPL=${EPYTHON}
+
+	configuring() {
+		local myconf=(
+			--disable-documentation
+		)
+		[[ ${EPYTHON} == ${SPHINX_IMPL} ]] &&
+			myconf+=( --enable-documentation )
+
+		econf "${myconf[@]}"
+	}
+	python_foreach_impl run_in_build_dir configuring
+}
+
+src_compile() {
+	python_foreach_impl run_in_build_dir default
+}
+
+src_test() {
+	unset DBUS_SESSION_BUS_ADDRESS
+	python_foreach_impl run_in_build_dir default
+}
+
+src_install() {
+	python_foreach_impl run_in_build_dir default
+	find "${D}" -name '*.la' -type f -delete || die
+
+	use examples && dodoc -r examples
+}
diff --git a/dev-python/dbus-python/files/dbus-python-1.2.16-py39.patch b/dev-python/dbus-python/files/dbus-python-1.2.16-py39.patch
new file mode 100644
index 000000000000..93db26cfcefc
--- /dev/null
+++ b/dev-python/dbus-python/files/dbus-python-1.2.16-py39.patch
@@ -0,0 +1,33 @@
+From 6a899a9174c8008ba5fb576238ea4d7c970453c3 Mon Sep 17 00:00:00 2001
+From: Simon McVittie <smcv@collabora.com>
+Date: Tue, 14 Jan 2020 15:29:43 +0000
+Subject: [PATCH] service: Adjust to deprecation of collections.Sequence
+
+Since Python 3.3 the recommended location is collections.abc.Sequence,
+and the collections.Sequence alias will be removed in 3.9.
+
+Signed-off-by: Simon McVittie <smcv@collabora.com>
+---
+ dbus/service.py | 6 +++++-
+ 1 file changed, 5 insertions(+), 1 deletion(-)
+
+diff --git a/dbus/service.py b/dbus/service.py
+index fd57054..0c8695a 100644
+--- a/dbus/service.py
++++ b/dbus/service.py
+@@ -32,7 +32,11 @@ import sys
+ import logging
+ import threading
+ import traceback
+-from collections import Sequence
++try:
++    from collections.abc import Sequence
++except ImportError:
++    # Python 2 (and 3.x < 3.3, but we don't support those)
++    from collections import Sequence
+ 
+ import _dbus_bindings
+ from dbus import (
+-- 
+2.26.2
+
diff --git a/dev-python/dbus-python/metadata.xml b/dev-python/dbus-python/metadata.xml
new file mode 100644
index 000000000000..09f999760bb3
--- /dev/null
+++ b/dev-python/dbus-python/metadata.xml
@@ -0,0 +1,12 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+  <maintainer type="project">
+    <email>freedesktop-bugs@gentoo.org</email>
+  </maintainer>
+<maintainer type="project">
+    <email>python@gentoo.org</email>
+    <name>Python</name>
+  </maintainer>
+	<origin>gentoo-staging</origin>
+</pkgmetadata>