Updating liguros repo

23 files changed, 657 insertions, 9 deletions

diff --git a/dev-lua/busted/busted-2.0.0-r101.ebuild b/dev-lua/busted/busted-2.0.0-r101.ebuild
new file mode 100644
index 000000000000..7abb3831d2ed
--- /dev/null
+++ b/dev-lua/busted/busted-2.0.0-r101.ebuild
@@ -0,0 +1,63 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+LUA_COMPAT=( lua5-{1..3} luajit )
+
+inherit lua toolchain-funcs
+
+DESCRIPTION="Elegant Lua unit testing"
+HOMEPAGE="https://olivinelabs.com/busted/"
+SRC_URI="https://github.com/Olivine-Labs/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~x86"
+IUSE="test"
+REQUIRED_USE="${LUA_REQUIRED_USE}"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	>=dev-lua/lua_cliargs-3.0_p2-r100[${LUA_USEDEP}]
+	>=dev-lua/luafilesystem-1.8.0-r100[${LUA_USEDEP}]
+	>=dev-lua/luasystem-0.2.1_p0-r100[${LUA_USEDEP}]
+	>=dev-lua/dkjson-2.5-r100[${LUA_USEDEP}]
+	>=dev-lua/say-1.3_p1-r100[${LUA_USEDEP}]
+	>=dev-lua/luassert-1.8.0-r100[${LUA_USEDEP}]
+	>=dev-lua/lua-term-0.7-r100[${LUA_USEDEP}]
+	>=dev-lua/penlight-1.7.0-r100[${LUA_USEDEP}]
+	>=dev-lua/mediator_lua-1.1.2_p0-r100[${LUA_USEDEP}]
+	${LUA_DEPS}
+"
+
+DEPEND="${RDEPEND}"
+
+BDEPEND="
+	virtual/pkgconfig
+	test? (
+		>=dev-lua/busted-2.0.0-r100
+		${RDEPEND}
+	)
+"
+
+lua_src_test() {
+	busted --lua=${ELUA} || die
+}
+
+src_test() {
+	lua_foreach_impl lua_src_test
+}
+
+lua_src_install() {
+	insinto $(lua_get_lmod_dir)
+	doins -r busted
+}
+
+src_install() {
+	dobin bin/busted
+
+	lua_foreach_impl lua_src_install
+
+	einstalldocs
+}
diff --git a/dev-lua/busted/metadata.xml b/dev-lua/busted/metadata.xml
index 07a585a9c990..d25c41808a07 100644
--- a/dev-lua/busted/metadata.xml
+++ b/dev-lua/busted/metadata.xml
@@ -5,7 +5,11 @@
 		<email>williamh@gentoo.org</email>
 		<name>William Hubbs</name>
 	</maintainer>
-	<longdescription lang="en">
+	<maintainer type="person">
+		<email>conikost@gentoo.org</email>
+		<name>Conrad Kostecki</name>
+	</maintainer>
+	<longdescription>
 		An elegant, extensible, testing framework.
 		Ships with a large amount of useful asserts,
 		plus the ability to write your own. Output
diff --git a/dev-lua/dkjson/dkjson-2.5-r100.ebuild b/dev-lua/dkjson/dkjson-2.5-r100.ebuild
new file mode 100644
index 000000000000..356fd0c66b8a
--- /dev/null
+++ b/dev-lua/dkjson/dkjson-2.5-r100.ebuild
@@ -0,0 +1,48 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+LUA_COMPAT=( lua5-{1..3} luajit )
+
+inherit lua toolchain-funcs
+
+DESCRIPTION="David Kolf's JSON module for Lua"
+HOMEPAGE="https://dkolf.de/src/dkjson-lua.fsl/"
+SRC_URI="http://dkolf.de/src/dkjson-lua.fsl/tarball/${P}.tar.gz?uuid=release_2_5 -> ${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~x86"
+IUSE="test"
+REQUIRED_USE="${LUA_REQUIRED_USE}"
+RESTRICT="!test? ( test )"
+
+RDEPEND="${LUA_DEPS}"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	virtual/pkgconfig
+	test? ( ${RDEPEND} )
+"
+
+DOCS=( "readme.txt" )
+
+lua_src_test() {
+	${ELUA} jsontest.lua || die
+	${ELUA} speedtest.lua ${PN} || die
+}
+
+src_test() {
+	lua_foreach_impl lua_src_test
+}
+
+lua_src_install() {
+	insinto $(lua_get_lmod_dir)
+	doins dkjson.lua
+}
+
+src_install() {
+	lua_foreach_impl lua_src_install
+
+	einstalldocs
+}
diff --git a/dev-lua/dkjson/metadata.xml b/dev-lua/dkjson/metadata.xml
index 95fd090f48de..8c66cb273b9b 100644
--- a/dev-lua/dkjson/metadata.xml
+++ b/dev-lua/dkjson/metadata.xml
@@ -5,7 +5,11 @@
 		<email>williamh@gentoo.org</email>
 		<name>William Hubbs</name>
 	</maintainer>
-	<longdescription lang="en">
+	<maintainer type="person">
+		<email>conikost@gentoo.org</email>
+		<name>Conrad Kostecki</name>
+	</maintainer>
+	<longdescription>
 		dkjson is a module for encoding and decoding JSON data. It supports
 		UTF-8.
 
diff --git a/dev-lua/lua-term/lua-term-0.7-r100.ebuild b/dev-lua/lua-term/lua-term-0.7-r100.ebuild
new file mode 100644
index 000000000000..5ced1bbb4f1a
--- /dev/null
+++ b/dev-lua/lua-term/lua-term-0.7-r100.ebuild
@@ -0,0 +1,66 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+LUA_COMPAT=( lua5-{1..3} luajit )
+MY_PV="0.07"
+MY_PV_SO="1.0.1"
+
+inherit lua toolchain-funcs
+
+DESCRIPTION="Terminal operations for Lua"
+HOMEPAGE="https://github.com/hoelzro/lua-term"
+SRC_URI="https://github.com/hoelzro/lua-term/archive/${MY_PV}.tar.gz -> ${P}.tar.gz"
+S="${WORKDIR}/${PN}-${MY_PV}"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~x86"
+REQUIRED_USE="${LUA_REQUIRED_USE}"
+
+RDEPEND="${LUA_DEPS}"
+DEPEND="${RDEPEND}"
+BDEPEND="virtual/pkgconfig"
+
+src_prepare() {
+	default
+
+	# Respect users CFLAGS
+	sed -e 's/-O3//g' -i Makefile
+}
+
+lua_src_compile() {
+	# Clean project to compile it for every lua slot
+	emake clean
+
+	local myemakeargs=(
+		"CC=$(tc-getCC)"
+		"CFLAGS=${CFLAGS} ${LDFLAGS} $(lua_get_CFLAGS)"
+	)
+
+	emake "${myemakeargs[@]}" all
+
+	# Copy module to match the choosen LUA implementation
+	cp "core.so.${MY_PV_SO}" "core-${ELUA}.so.${MY_PV_SO}" || die
+}
+
+src_compile() {
+	lua_foreach_impl lua_src_compile
+}
+
+lua_src_install() {
+	# Use correct module for the choosen LUA implementation
+	cp "core-${ELUA}.so.${MY_PV_SO}" "core.so.${MY_PV_SO}" || die
+
+	local myemakeargs=(
+		LUA_LIBDIR="${ED}/$(lua_get_cmod_dir)/term"
+		LUA_SHARE="${ED}/$(lua_get_lmod_dir)/term"
+	)
+
+	emake "${myemakeargs[@]}" install
+}
+
+src_install() {
+	lua_foreach_impl lua_src_install
+}
diff --git a/dev-lua/lua-term/metadata.xml b/dev-lua/lua-term/metadata.xml
index 5ffafc6620aa..5a2bb678a070 100644
--- a/dev-lua/lua-term/metadata.xml
+++ b/dev-lua/lua-term/metadata.xml
@@ -5,6 +5,10 @@
 		<email>williamh@gentoo.org</email>
 		<name>William Hubbs</name>
 	</maintainer>
+	<maintainer type="person">
+		<email>conikost@gentoo.org</email>
+		<name>Conrad Kostecki</name>
+	</maintainer>
 	<upstream>
 		<remote-id type="github">hoelzro/lua-term</remote-id>
 	</upstream>
diff --git a/dev-lua/lua_cliargs/lua_cliargs-3.0_p2-r100.ebuild b/dev-lua/lua_cliargs/lua_cliargs-3.0_p2-r100.ebuild
new file mode 100644
index 000000000000..471bebcf2aa6
--- /dev/null
+++ b/dev-lua/lua_cliargs/lua_cliargs-3.0_p2-r100.ebuild
@@ -0,0 +1,37 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+LUA_COMPAT=( lua5-{1..3} luajit )
+MY_PV="${PV/_p/-}"
+
+inherit lua toolchain-funcs
+
+DESCRIPTION="A command-line argument parsing module for Lua"
+HOMEPAGE="https://github.com/amireh/lua_cliargs"
+SRC_URI="https://github.com/amireh/${PN}/archive/v${MY_PV}.tar.gz -> ${P}.tar.gz"
+S="${WORKDIR}/${PN}-${MY_PV}"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~x86"
+IUSE="examples"
+REQUIRED_USE="${LUA_REQUIRED_USE}"
+
+RDEPEND="${LUA_DEPS}"
+BDEPEND="virtual/pkgconfig"
+
+HTML_DOCS=( "doc/." )
+
+lua_src_install() {
+	insinto $(lua_get_lmod_dir)
+	doins -r src/.
+}
+
+src_install() {
+	lua_foreach_impl lua_src_install
+
+	use examples && dodoc -r examples
+	einstalldocs
+}
diff --git a/dev-lua/lua_cliargs/metadata.xml b/dev-lua/lua_cliargs/metadata.xml
index 6f4ebc9b59a3..78c5df74a24d 100644
--- a/dev-lua/lua_cliargs/metadata.xml
+++ b/dev-lua/lua_cliargs/metadata.xml
@@ -5,7 +5,11 @@
 		<email>williamh@gentoo.org</email>
 		<name>William Hubbs</name>
 	</maintainer>
-	<longdescription lang="en">
+	<maintainer type="person">
+		<email>conikost@gentoo.org</email>
+		<name>Conrad Kostecki</name>
+	</maintainer>
+	<longdescription>
 		This module adds support for accepting CLI
 		arguments easily using multiple notations and argument types.
 
diff --git a/dev-lua/luadbi/luadbi-0.7.2-r100.ebuild b/dev-lua/luadbi/luadbi-0.7.2-r101.ebuild
index f7f3c1fdcab6..f19a4a0b67ff 100644
--- a/dev-lua/luadbi/luadbi-0.7.2-r100.ebuild
+++ b/dev-lua/luadbi/luadbi-0.7.2-r101.ebuild
@@ -33,7 +33,7 @@ DEPEND="${RDEPEND}"
 BDEPEND="
 	virtual/pkgconfig
 	test? (
-		dev-lua/busted
+		>=dev-lua/busted-2.0.0-r100[${LUA_USEDEP}]
 		dev-lua/luarocks
 	)
 "
diff --git a/dev-lua/luasec/luasec-0.9-r100.ebuild b/dev-lua/luasec/luasec-0.9-r101.ebuild
index d908b664a4c5..ee3f8ffb8613 100644
--- a/dev-lua/luasec/luasec-0.9-r100.ebuild
+++ b/dev-lua/luasec/luasec-0.9-r101.ebuild
@@ -19,7 +19,7 @@ IUSE="libressl"
 REQUIRED_USE="${LUA_REQUIRED_USE}"
 
 RDEPEND="
-	>=dev-lua/luasocket-3.0_rc1_p20200328-r100
+	>=dev-lua/luasocket-3.0_rc1_p20200328-r100[${LUA_USEDEP}]
 	libressl? ( dev-libs/libressl:= )
 	!libressl? ( dev-libs/openssl:0= )
 	${LUA_DEPS}
diff --git a/dev-lua/luassert/files/luassert-1.8.0-disable-highlightcolor-test.patch b/dev-lua/luassert/files/luassert-1.8.0-disable-highlightcolor-test.patch
new file mode 100644
index 000000000000..fe3f7815a04e
--- /dev/null
+++ b/dev-lua/luassert/files/luassert-1.8.0-disable-highlightcolor-test.patch
@@ -0,0 +1,57 @@
+--- a/spec/formatters_spec.lua
++++ b/spec/formatters_spec.lua
+@@ -102,18 +102,6 @@
+     assert.is.equal(expected, formatted)
+   end)
+ 
+-  it("Checks to see if TableErrorHighlightColor changes error color", function()
+-    local ok, colors = pcall(require, "term.colors")
+-    if not ok then pending("lua term.colors not available") end
+-
+-    assert:set_parameter("TableErrorHighlightColor", "red")
+-    local t = {1,2,3}
+-    local fmtargs = { {crumbs = {2}} }
+-    local formatted = assert:format({t, n = 1, fmtargs = fmtargs})[1]
+-    local expected = string.format("("..tostring(t)..") {\n  [1] = 1\n %s[2] = 2\n  [3] = 3 }", colors.red("*"))
+-    assert.is.equal(expected, formatted)
+-  end)
+-
+   it("Checks to see if self referencing tables can be formatted", function()
+     local t = {1,2}
+     t[3] = t
+--- a/spec/assertions_spec.lua
++++ b/spec/assertions_spec.lua
+@@ -472,17 +472,6 @@
+     assert.no_error_matches(t_ok, ".*")
+   end)
+ 
+-  it("Checks error_matches compares error strings with pattern", function()
+-    assert.error_matches(function() error() end, nil)
+-    assert.no_error_matches(function() end, nil)
+-    assert.does_error_match(function() error(123) end, "^%d+$")
+-    assert.error.matches(function() error("string") end, "^%w+$")
+-    assert.matches.error(function() error("string") end, "str", nil, true)
+-    assert.matches_error(function() error("123string") end, "^[^0-9]+", 4)
+-    assert.has_no_error.match(function() error("123string") end, "123", 4, true)
+-    assert.does_not.match_error(function() error("string") end, "^%w+$", nil, true)
+-  end)
+-
+   it("Checks error_matches does not compare error objects", function()
+     local func = function() end
+     assert.no_error_matches(function() error({ "table" }) end, "table")
+@@ -557,15 +546,6 @@
+     assert.is_same({}, {assert.has_no_match("%d+", "string", nil, true, "message")})
+   end)
+ 
+-  it("Checks assert.has_error returns thrown error on success", function()
+-    assert.is_same({"err message", "err message"}, {assert.has_error(function() error("err message") end, "err message")})
+-    assert.is_same({"err", "err"}, {assert.has_error(function() error(setmetatable({},{__tostring = function() return "err" end})) end, "err")})
+-    assert.is_same({{}, {}}, {assert.has_error(function() error({}) end, {})})
+-    assert.is_same({'0', 0}, {assert.has_error(function() error(0) end, 0)})
+-    assert.is_same({nil, nil}, {assert.has_error(function() error(nil) end, nil)})
+-    assert.is_same({nil, "string"}, {assert.has_no_error(function() end, "string")})
+-  end)
+-
+   it("Checks assert.error_matches returns captures of thrown error on success", function()
+     assert.is_same({"err", "message"}, {assert.error_matches(function() error("err message") end, "(err) (%w+)$")})
+     assert.is_same({"err"}, {assert.error_matches(function() error(setmetatable({},{__tostring = function() return "err" end})) end, "err", nil, true)})
diff --git a/dev-lua/luassert/luassert-1.8.0-r101.ebuild b/dev-lua/luassert/luassert-1.8.0-r101.ebuild
new file mode 100644
index 000000000000..cd8e9a8e6cc9
--- /dev/null
+++ b/dev-lua/luassert/luassert-1.8.0-r101.ebuild
@@ -0,0 +1,55 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+LUA_COMPAT=( lua5-{1..3} luajit )
+
+inherit lua toolchain-funcs
+
+DESCRIPTION="Assertion library for Lua"
+HOMEPAGE="https://olivinelabs.com/busted/"
+SRC_URI="https://github.com/Olivine-Labs/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~x86"
+IUSE="test"
+REQUIRED_USE="${LUA_REQUIRED_USE}"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	>=dev-lua/say-1.3_p1-r100[${LUA_USEDEP}]
+	${LUA_DEPS}
+"
+
+BDEPEND="
+	virtual/pkgconfig
+	test? (
+		>=dev-lua/busted-2.0.0-r100[${LUA_USEDEP}]
+		${RDEPEND}
+	)
+"
+
+DEPEND="${RDEPEND}"
+
+PATCHES=( "${FILESDIR}/${PN}-1.8.0-disable-highlightcolor-test.patch" )
+
+lua_src_test() {
+	busted --lua=${ELUA} || die
+}
+
+src_test() {
+	lua_foreach_impl lua_src_test
+}
+
+lua_src_install() {
+	insinto $(lua_get_lmod_dir)/luassert
+	doins -r src/.
+
+	einstalldocs
+}
+
+src_install() {
+	lua_foreach_impl lua_src_install
+}
diff --git a/dev-lua/luassert/metadata.xml b/dev-lua/luassert/metadata.xml
index d900590e16ce..9beb120d5bf4 100644
--- a/dev-lua/luassert/metadata.xml
+++ b/dev-lua/luassert/metadata.xml
@@ -5,7 +5,11 @@
 		<email>williamh@gentoo.org</email>
 		<name>William Hubbs</name>
 	</maintainer>
-	<longdescription lang="en">
+	<maintainer type="person">
+		<email>conikost@gentoo.org</email>
+		<name>Conrad Kostecki</name>
+	</maintainer>
+	<longdescription>
 		Adds a framework that allows registering new assertions
 		without compromising builtin assertion functionality.
 	</longdescription>
diff --git a/dev-lua/luasystem/luasystem-0.2.1_p0-r101.ebuild b/dev-lua/luasystem/luasystem-0.2.1_p0-r101.ebuild
new file mode 100644
index 000000000000..cbc542df1f37
--- /dev/null
+++ b/dev-lua/luasystem/luasystem-0.2.1_p0-r101.ebuild
@@ -0,0 +1,84 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+LUA_COMPAT=( lua5-{1..3} luajit )
+MY_PV="${PV/_p/-}"
+
+inherit lua toolchain-funcs
+
+DESCRIPTION="Platform independent system calls for Lua"
+HOMEPAGE="https://github.com/o-lim/luasystem/"
+SRC_URI="https://github.com/o-lim/${PN}/archive/v${MY_PV}.tar.gz -> ${P}.tar.gz"
+S="${WORKDIR}/${PN}-${MY_PV}"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~x86"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="${LUA_DEPS}"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	virtual/pkgconfig
+	test? (
+		>=dev-lua/busted-2.0.0-r100[${LUA_USEDEP}]
+		${RDEPEND}
+	)
+"
+
+PATCHES=( "${FILESDIR}"/${P}-fix-makefile.patch )
+
+lua_src_test() {
+	busted --lua=${ELUA} || die
+}
+
+src_test() {
+	lua_foreach_impl lua_src_test
+}
+
+lua_src_compile() {
+	# Clean project, to compile it for every lua slot
+	emake clean
+
+	local myemakeargs=(
+		"CC=$(tc-getCC)"
+		"LD=$(tc-getCC)"
+		"LUAINC_linux=$(lua_get_include_dir)"
+		"MYCFLAGS=${CFLAGS}"
+		"MYLDFLAGS=${LDFLAGS}"
+	)
+
+	emake "${myemakeargs[@]}" linux
+
+	# Copy module to match the choosen LUA implementation
+	cp "src/core.so" "src/core-${ELUA}.so" || die
+}
+
+src_compile() {
+	lua_foreach_impl lua_src_compile
+}
+
+lua_src_install () {
+	# Use correct module for the choosen LUA implementation
+	cp "src/core-${ELUA}.so" "src/core.so" || die
+
+	local emakeargs=(
+		"INSTALL_TOP_CDIR=${ED}/$(lua_get_cmod_dir)"
+		"INSTALL_TOP_LDIR=${ED}/$(lua_get_lmod_dir)"
+		"LUA_INC=${ED}/$(lua_get_include_dir)"
+	)
+
+	emake "${emakeargs[@]}" install
+
+	insinto $(lua_get_lmod_dir)/system
+	doins system/init.lua
+}
+
+src_install() {
+	lua_foreach_impl lua_src_install
+
+	einstalldocs
+}
diff --git a/dev-lua/luasystem/metadata.xml b/dev-lua/luasystem/metadata.xml
index e95c199348ec..8e137a07353c 100644
--- a/dev-lua/luasystem/metadata.xml
+++ b/dev-lua/luasystem/metadata.xml
@@ -5,7 +5,11 @@
 		<email>williamh@gentoo.org</email>
 		<name>William Hubbs</name>
 	</maintainer>
-	<longdescription lang="en">
+	<maintainer type="person">
+		<email>conikost@gentoo.org</email>
+		<name>Conrad Kostecki</name>
+	</maintainer>
+	<longdescription>
 		luasystem is a platform independent system call library for Lua.
 		Supports Lua >= 5.1 and luajit >= 2.0.0.
 	</longdescription>
diff --git a/dev-lua/mediator_lua/mediator_lua-1.1.2_p0-r101.ebuild b/dev-lua/mediator_lua/mediator_lua-1.1.2_p0-r101.ebuild
new file mode 100644
index 000000000000..6ac77cd0aca9
--- /dev/null
+++ b/dev-lua/mediator_lua/mediator_lua-1.1.2_p0-r101.ebuild
@@ -0,0 +1,49 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+LUA_COMPAT=( lua5-{1..3} luajit )
+MY_PV="${PV/_p/-}"
+
+inherit lua toolchain-funcs
+
+DESCRIPTION="Mediator pattern implementation for pub-sub management "
+HOMEPAGE="https://olivinelabs.com/mediator_lua/"
+SRC_URI="https://github.com/Olivine-Labs/${PN}/archive/v${MY_PV}.tar.gz -> ${P}.tar.gz"
+S="${WORKDIR}/${PN}-${MY_PV}"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~x86"
+IUSE="test"
+REQUIRED_USE="${LUA_REQUIRED_USE}"
+RESTRICT="!test? ( test )"
+
+RDEPEND="${LUA_DEPS}"
+BDEPEND="
+	virtual/pkgconfig
+	test? (
+		>=dev-lua/busted-2.0.0-r100[${LUA_USEDEP}]
+		${RDEPEND}
+	)
+"
+
+lua_src_test() {
+	busted --lua=${ELUA} || die
+}
+
+src_test() {
+	lua_foreach_impl lua_src_test
+}
+
+lua_src_install() {
+	insinto $(lua_get_lmod_dir)
+	doins src/mediator.lua
+}
+
+src_install() {
+	lua_foreach_impl lua_src_install
+
+	einstalldocs
+}
diff --git a/dev-lua/mediator_lua/metadata.xml b/dev-lua/mediator_lua/metadata.xml
index 1a278a01eaf1..9bcbc496abb1 100644
--- a/dev-lua/mediator_lua/metadata.xml
+++ b/dev-lua/mediator_lua/metadata.xml
@@ -5,7 +5,11 @@
 		<email>williamh@gentoo.org</email>
 		<name>William Hubbs</name>
 	</maintainer>
-	<longdescription lang="en">
+	<maintainer type="person">
+		<email>conikost@gentoo.org</email>
+		<name>Conrad Kostecki</name>
+	</maintainer>
+	<longdescription>
 		mediator_lua allows you to subscribe and publish to a central object so
 		you can decouple function calls in your application. It's as simple as
 		mediator:subscribe("channel", function). Supports namespacing, predicates,
diff --git a/dev-lua/penlight/Manifest b/dev-lua/penlight/Manifest
index d348b03ca142..6ea12b1323bc 100644
--- a/dev-lua/penlight/Manifest
+++ b/dev-lua/penlight/Manifest
@@ -1,3 +1,4 @@
 DIST penlight-1.3.2-core.zip 116854 BLAKE2B c653a51cf8ea286c849e1a2c68968ed767c350b1461dd11d9a2e99c81295461c67044175c7bf99c31e8040118e6cfce85f8613d4b6c49e726d31393029abcbbf SHA512 01ba35e967e255f6f39afff9c2238f4921de9e52850ce0d2ec0c9068029fc61a241c82bede680a28fda46c4504582784fcd2241a2eef0bef95c7c389c4042d02
 DIST penlight-1.5.4.tar.gz 213938 BLAKE2B c6bba4fd7fc491d2e6ca464f71b897ba4b5dc8dc94e7340fd77d3add47a9b4a72ce48cea268f94fe55c2aef1edd850f96f00f2ba1ef7186e1e8d86a4e3155366 SHA512 c46e7875410a90390bfbf010a53f1d536475e2094668722618d03951caad0fcb0674c9bc7119a0753e4ed3df9e4d70fef828ba4c6c24e8ada4036948d2432519
 DIST penlight-1.7.0.tar.gz 384917 BLAKE2B 153660f5029509611265399aad8b92d82b266ac470414c06e9d7f01b37225834f98488f30f9bbdfdc3a6714edfe2edc0fccd0356ebb966d964be633bff38eb25 SHA512 edeb09307c9feb5da6bccd82216a6ad71db988c433245d72d28abb6c555004f77eebba556928b0912937b29ef93e065ad491368041e17730610813de8e595d7d
+DIST penlight-1.9.2.tar.gz 396248 BLAKE2B 2bbbece6e9855e8fc54f22f01e516cdf886782ec9a007a4ffac8ac980d7e0836cd19b8a7659ab1e05331e12b11bdb1c9c7df5e2f03c39965532c381298017035 SHA512 8df26e74f73ccf6dc73546640e1537b63e40357072855f9409e96b2ef8251c25b4653456d1237d5142573618af242e885490aa9750dffb387e4670ed9f3cfa91
diff --git a/dev-lua/penlight/metadata.xml b/dev-lua/penlight/metadata.xml
index 4ddf99c5f8a0..5e6a08337e1c 100644
--- a/dev-lua/penlight/metadata.xml
+++ b/dev-lua/penlight/metadata.xml
@@ -5,7 +5,11 @@
 		<email>williamh@gentoo.org</email>
 		<name>William Hubbs</name>
 	</maintainer>
-	<longdescription lang="en">
+	<maintainer type="person">
+		<email>conikost@gentoo.org</email>
+		<name>Conrad Kostecki</name>
+	</maintainer>
+	<longdescription>
 		Penlight is a set of pure Lua libraries for making it easier to work
 		with common tasks like iterating over directories, reading
 		configuration files and the like. Provides functional operations
diff --git a/dev-lua/penlight/penlight-1.9.2-r101.ebuild b/dev-lua/penlight/penlight-1.9.2-r101.ebuild
new file mode 100644
index 000000000000..fc399a4a51d6
--- /dev/null
+++ b/dev-lua/penlight/penlight-1.9.2-r101.ebuild
@@ -0,0 +1,57 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+LUA_COMPAT=( lua5-{1..3} luajit )
+MY_PN="Penlight"
+
+inherit lua toolchain-funcs
+
+DESCRIPTION="Lua utility libraries loosely based on the Python standard libraries"
+HOMEPAGE="https://github.com/Tieske/Penlight",
+SRC_URI="https://github.com/Tieske/${MY_PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+S="${WORKDIR}/${MY_PN}-${PV}"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~x86"
+IUSE="test"
+REQUIRED_USE="${LUA_REQUIRED_USE}"
+RESTRICT="!test? ( test )"
+
+DEPEND="${LUA_DEPS}"
+
+RDEPEND="
+	>=dev-lua/luafilesystem-1.8.0-r100
+	${DEPEND}
+"
+
+BDEPEND="
+	virtual/pkgconfig
+	test? ( ${DEPEND} )
+"
+
+HTML_DOCS=( "docs/." )
+
+lua_src_test() {
+	${ELUA} run.lua || die
+}
+
+src_test() {
+	# This is a demo app, not a real test
+	rm tests/test-app.lua
+
+	lua_foreach_impl lua_src_test
+}
+
+lua_src_install() {
+	insinto $(lua_get_lmod_dir)
+	doins -r lua/pl
+
+	einstalldocs
+}
+
+src_install() {
+	lua_foreach_impl lua_src_install
+}
diff --git a/dev-lua/penlight/penlight-1.9.2.ebuild b/dev-lua/penlight/penlight-1.9.2.ebuild
new file mode 100644
index 000000000000..a679ab743c3a
--- /dev/null
+++ b/dev-lua/penlight/penlight-1.9.2.ebuild
@@ -0,0 +1,47 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+MY_PN="Penlight"
+
+inherit toolchain-funcs
+
+DESCRIPTION="Lua utility libraries loosely based on the Python standard libraries"
+HOMEPAGE="https://github.com/Tieske/Penlight",
+SRC_URI="https://github.com/Tieske/${MY_PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+S="${WORKDIR}/${MY_PN}-${PV}"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~x86"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+DEPEND=">=dev-lang/lua-5.1:="
+
+RDEPEND="
+	dev-lua/luafilesystem
+	${DEPEND}
+"
+
+BDEPEND="
+	virtual/pkgconfig
+	test? ( ${DEPEND} )
+"
+
+HTML_DOCS=( "docs/." )
+
+src_test() {
+	# This is a demo app, not a real test
+	rm tests/test-app.lua
+
+	lua run.lua || die
+}
+
+src_install() {
+	insinto "$($(tc-getPKG_CONFIG) --variable INSTALL_LMOD lua)"
+	doins -r lua/pl
+
+	einstalldocs
+}
diff --git a/dev-lua/say/metadata.xml b/dev-lua/say/metadata.xml
index d0c9f09644c7..3c38696faaa4 100644
--- a/dev-lua/say/metadata.xml
+++ b/dev-lua/say/metadata.xml
@@ -5,6 +5,10 @@
 		<email>williamh@gentoo.org</email>
 		<name>William Hubbs</name>
 	</maintainer>
+	<maintainer type="person">
+		<email>conikost@gentoo.org</email>
+		<name>Conrad Kostecki</name>
+	</maintainer>
 	<upstream>
 		<remote-id type="github">Olivine-Labs/say</remote-id>
 	</upstream>
diff --git a/dev-lua/say/say-1.3_p1-r101.ebuild b/dev-lua/say/say-1.3_p1-r101.ebuild
new file mode 100644
index 000000000000..d172354299e5
--- /dev/null
+++ b/dev-lua/say/say-1.3_p1-r101.ebuild
@@ -0,0 +1,48 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+LUA_COMPAT=( lua5-{1..3} luajit )
+MY_PV="${PV/_p/-}"
+
+inherit lua toolchain-funcs
+
+DESCRIPTION="Lua String Hashing/Indexing Library"
+HOMEPAGE="https://olivinelabs.com/busted/"
+SRC_URI="https://github.com/Olivine-Labs/${PN}/archive/v${MY_PV}.tar.gz -> ${P}.tar.gz"
+S="${WORKDIR}/${PN}-${MY_PV}"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~x86"
+IUSE="test"
+REQUIRED_USE="${LUA_REQUIRED_USE}"
+RESTRICT="!test? ( test )"
+
+RDEPEND="${LUA_DEPS}"
+
+BDEPEND="
+	virtual/pkgconfig
+	test? ( >=dev-lua/busted-2.0.0-r100[${LUA_USEDEP}] )
+	${RDEPEND}
+"
+
+lua_src_test() {
+	busted --lua=${ELUA} || die
+}
+
+src_test() {
+	lua_foreach_impl lua_src_test
+}
+
+lua_src_install() {
+	insinto $(lua_get_lmod_dir)/say
+	doins src/init.lua
+
+	einstalldocs
+}
+
+src_install() {
+	lua_foreach_impl lua_src_install
+}